复制文件列表 (txt)

Question

我见过一些脚本示例，但似乎没有一个提供如何从 .t​​xt 列表中读取文件名的示例。

这个例子很好，以便将所有文件从 A 文件夹复制到 B 文件夹

xcopy c:\olddir\*.java c:\newdir /D /E /Q /Y

但我需要类似下一个的东西，我可以在其中实际填充源文件夹和目标文件夹：

 @echo off
 set src_folder = c:\whatever\*.*
 set dst_folder = c:\foo
 xcopy /S/E/U %src_folder% %dst_folder%

而不是 src_folder = c:\whatever\*。 *，那些*.*需要是从txt文件读取的文件列表。

File-list.txt（示例）

file1.pds
filex.pbd
blah1.xls

有人可以建议我该怎么做吗？

Answer 1

给定名为 File-list.txt 的文件中的文件名列表，以下几行应该执行您想要的操作：

@echo off
set src_folder=c:\whatever
set dst_folder=c:\target
for /f "tokens=*" %%i in (File-list.txt) DO (
    xcopy /S/E "%src_folder%\%%i" "%dst_folder%"
)

Answer 2

我只是尝试使用 Frank Bollack 和 sparrowt 的答案，但没有成功，因为它包含 xcopy 的 /U 开关。据我了解， /U 意味着只有当文件已存在于目标中时才会复制这些文件，这对我来说不是这种情况，而且对于原始提问者来说似乎也不是这种情况。它可能意味着 /V 表示验证，这更有意义。

删除 /U 开关解决了该问题。

@echo off
set src_folder=c:\whatever
set dst_folder=c:\target
for /f "tokens=*" %%i in (File-list.txt) DO (
xcopy /S/E "%src_folder%\%%i" "%dst_folder%"
)

Answer 3

这将做到这一点：

@echo off
set src_folder=c:\batch
set dst_folder=c:\batch\destination
set file_list=c:\batch\file_list.txt

if not exist "%dst_folder%" mkdir "%dst_folder%"

for /f "delims=" %%f in (%file_list%) do (
    xcopy "%src_folder%\%%f" "%dst_folder%\"
)

Answer 4

以下将从列表中复制文件并保留目录结构。例如，当您需要压缩在一系列 Git/SVN 提交中更改的文件时很有用。它还将处理目录/文件名中的空格，并适用于相对路径和绝对路径：

（基于这个问题：如何在批处理文件中的 for 循环内扩展两个局部变量)

@echo off

setlocal enabledelayedexpansion

set "source=input dir"
set "target=output dir"

for /f "tokens=* usebackq" %%A in ("file_list.txt") do (
    set "FILE=%%A"
    set "dest_file_full=%target%\!FILE:%source%=!"
    set "dest_file_filename=%%~nxA"
    call set "dest_file_dir=%%dest_file_full:!dest_file_filename!=%%"
    if not exist "!dest_file_dir!" (
        md "!dest_file_dir!"
    )
    set "source_file_full=%source%\!FILE:%source%=!"
    copy "!source_file_full!" "!dest_file_dir!"
)
pause

请注意，如果您的文件列表具有绝对路径，则必须将 source 设置为绝对路径，如下所示出色地。

[¹] 如果使用 Git，请参阅：仅导出在 Git 中具有文件夹结构的已修改和添加的文件

Answer 5

这也将保留文件的原始文件目录：

@echo off
set src_folder=c:\whatever
set dst_folder=c:\target
set file_list=C:\file_list.txt

for /f "tokens=*" %%i in (%file_list%) DO (
   echo f | xcopy /E /C /R /Y "%src_folder%\%%i" "%dst_folder%\%%i"
)

Answer 6

也可以使用robocopy并且不使用for循环与xcopy - 可以解析参数中的文件列表。

robocopy Source_folder Destination_folder [files_to_copy] [options]

用于复制带有空格分隔符的字符串的文件。
例如：

robocopy . "d:\my folder" *.txt "my file one.cpp" file2.cpp
robocopy "d:\F 15" "d:\backup\F 15" /E