如何使用在 MSXML 和 libxml 上运行的 node-set() 函数编写 XSL 1.0 样式表

Question

我有一个使用 PHP (libxml) 附带的 XSL 处理器运行的 XSLT 1.0 样式表。我希望获得相同的样式表以在 Microsoft XSL 处理器 MSXML 6.0 (msxml6.dll) 上运行（理想情况下），以便相同的样式表可以在任一处理器上运行。

不幸的是，目前我需要两个样式表 - 每个处理器一个。

此代码片段调用 PHP 处理器上的 node-set() 函数；

<xsl:transform version="1.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:exsl="http://exslt.org/common"
  extension-element-prefixes="exsl">
    <xsl:template match="root">
        <xsl:variable name="rtf">
            <a>hello</a><b>world</b>
        </xsl:variable>
        <xsl:variable name="ns" select="exsl:node-set($rtf)"/>
        <xsl:copy-of select="$ns/b"/>
    </xsl:template>
</xsl:transform>

此代码片段调用 Microsoft 处理器上的 node-set() 函数；

<xsl:transform version="1.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:msxsl="urn:schemas-microsoft-com:xslt"
  extension-element-prefixes="msxsl">
    <xsl:template match="root">
        <xsl:variable name="rtf">
            <a>hello</a><b>world</b>
        </xsl:variable>
        <xsl:variable name="ns" select="msxsl:node-set($rtf)"/>
        <xsl:copy-of select="$ns/b"/>
    </xsl:template>
</xsl:transform>

如果输入文档是；

<root/>

两个样式表的结果都是：

<b>world</b>

我想要一个可以在 PHP 处理器和 Microsoft 处理器上不加修改地运行的单个样式表。

尽管我的真实样式表大约有 400 行长，并且在四个地方使用了 node-set() 函数，但我希望上面的示例能够说明问题。

Answer 1

检查了 libxml 和 msxsl，在两种情况下都有效。

问候

迈克。

<xsl:transform version="1.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:exsl="http://exslt.org/common"
  xmlns:func="http://exslt.org/functions"
  xmlns:msxsl="urn:schemas-microsoft-com:xslt"
  extension-element-prefixes="exsl func msxsl"
  >

    <func:function name="msxsl:node-set">
      <xsl:param name="node"/>
      <func:result select="exsl:node-set($node)"/>
    </func:function>

    <xsl:template match="root">
        <xsl:variable name="rtf">
            <a>hello</a><b>world</b>
        </xsl:variable>
        <xsl:variable name="ns" select="msxsl:node-set($rtf)"/>
        <xsl:copy-of select="$ns/b"/>
    </xsl:template>
</xsl:transform>