搜索数组中连续元素的索引

Question

所以我有一个数组my @a = (a,b,c,d,e,f)
另一个数组 my @b = (c,d,e)

我想查找 @a 中是否有三个连续元素与 @b 中的元素匹配。 然后，如果有，我想获取这些元素所在的索引。

因此，在上面的情况下，我想获取一个数组，例如 (2,3,4)。

另一个例子：
我的@a = (1,2,3,4,5)
my @b = (2,3)

输出：(1,2)

Answer 1

一种幼稚的方法：

@A = 1..5;
@B = 2..3;
A_LOOP:
for my $a_index (0..$#A) {
    for my $b_index (0..$#B) {
        next A_LOOP unless $A[$a_index+$b_index] eq $B[$b_index];
    }
    @results = map $a_index+$_, 0..$#B;
    last;
}

如果这不够快（鉴于您的示例，不太可能）， Boyer-Moore 实施起来并不困难。

Answer 2

这是一个通用的解决方案。这使用 List::MoreUtils 中的“all”函数来减少与真/假结果的比较，从而稍微简化了逻辑。

我将其放入子形式中，您可以向其中传递对任意两个数组的引用。传递给函数的第一个数组 ref 应该是超集，第二个数组 ref 应该引用子集数组。

我喜欢这个解决方案的原因是它可以应用于任何两个简单数组（例如，它不限于寻找二元素子集）。我确实选择了元素的字符串比较（eq）而不是数字（==）。这样，如果您有非数字元素，它就可以工作。但是，它会将“00”和“0”评估为不相等（因为它们不是同一字符串）。如果您喜欢数字比较，只需找到“eq”并将其更改为“==”即可。

这是代码：

use 5.010_001;
use strict;
use warnings;

use List::MoreUtils qw/all/;

my @array_a = qw/1 2 3 4 5/;
my @array_b = qw/2 3/;

{
    local $, = " ";
    my( @results ) = find_group( \@array_a, \@array_b );
    say "Success at ", @results if @results;
}


sub find_group {
    my( $array_1, $array_2 ) = @_;
    foreach my $array_1_idx ( 0 .. $#{$array_1} ) {
        my $moving_idx = $array_1_idx;
        return $array_1_idx .. ( $moving_idx - 1 ) if 
            all { $_ eq $array_1->[$moving_idx++] } @{$array_2};
    }
    return ();
}