如何引用项目来统计收件箱中的邮件数量？

Question

一个小错误导致该计数代码无法运行。

Sub Count2
  Dim objOutlook As Object, objnSpace As Object, objFolder As Object
  Dim Count As Integer
  Set objOutlook = CreateObject("Outlook.Application")
  Set objnSpace = objOutlook.GetNamespace("MAPI")

  Set objFolder = objnSpace.Folders("My Personal Emails").Folders("spam")
  If Err.Number <> 0 Then
    Err.Clear
    MsgBox "No such folder."
    Exit Sub
  End If

  For Each MapiItem In MapiFolderInbox.Messages
  Select Case Weekday(MapiItem.TimeReceived)
    Case vbMonday
      Count = Count + 1
    End Select
  Next MapiItem

  MsgBox "Number of spam messages sent on a Monday: " & Count
End Sub

错误信息：

运行时错误“424”： 需要对象

调试器突出显示该行：

For Each MapiItem In MapiFolderInbox.Messages

Answer 1

好的，这是一个工作版本：

Sub Count2()

Dim i As Integer, Count As Integer
Dim objOutlook As Outlook.Application
Dim objNSpace As Outlook.NameSpace
Dim objFolder As Outlook.Folder

Set objOutlook = CreateObject("Outlook.Application")
Set objNSpace = objOutlook.GetNamespace("MAPI")
Set objFolder = objNSpace.Folders("My Personal Emails").Folders("spam")

Count = 0
For i = 1 To objFolder.Items.count

  If Weekday(objFolder.Items(i).ReceivedTime) = vbMonday Then
    Count = Count + 1
  End If

Next i

MsgBox "Number of spam messages sent on a Monday: " & Count

End Sub

Answer 2

编辑：--根据 VBA 代码中的最后一个字符串判断，您似乎希望对垃圾邮件进行计数。使用 @sitnik 的解决方案似乎是更好的方法。

MapiFolderInbox 似乎未定义 - 尝试将其分配给您的收件箱文件夹，例如：

 Set MapiFolderInbox = objnSpace.Folders("My Personal Emails").Folders("Inbox")

另请参阅：选项显式打开