如何使标题图标在 Flex 3 面板中居中？

Question

如何使标题图标在 Flex 3 面板中居中？标题居中，但标题图标位于面板的左侧。

<mx:Panel  
    title="{myTitle}"    
    textAlign="center"
    titleStyleName="panelTitle" 
    titleIcon="{myIcon}"
    >   


.panelTitle {
    font-size: 14;
    fontFamily: "Lucida Grande";
}   

编辑：我正在尝试让 www.flextras.com 建议发挥作用。这就是我得到的：

package com.mysite.components
{
    import mx.containers.Panel;

    public class CenterTitleIconPanel extends Panel
    {

        override protected function layoutChrome(unscaledWidth:Number, unscaledHeight:Number):void {
            super.layoutChrome(unscaledWidth,unscaledHeight);
                if (titleIconObject)
                {
                    titleIconObject.move((unscaledWidth-titleIconObject.width)/2,(unscaledHeight-titleIconObject.height)/2);
                }
        }


        public function CenterTitleIconPanel()
        {
            super();
        }

    }
}

但是，我收到错误 1178：

1178：尝试访问无法访问的内容 属性 titleIconObject 通过 静态类型的引用 com.mysite.components:CenterTitleIconPanel。

有什么建议吗？谢谢。

Answer 1

扩展组件并重写layoutChrome方法以重新定位titleIcon。

大致是这样的：

override protected function layoutChrome(unscaledWidth:Number,
                                             unscaledHeight:Number):void{
 super.layoutChrone(unscaledWidth,unscaledHeight);
            if (titleIconObject)
            {
                titleIconObject.move((unscaledWidth-titleIconObject.width)/2,(unscaledHeight-titleIconObject.height)/2);
            }
 }

基本上，我采用组件的 unscaledWidth，减去 titleIconObject 的宽度，然后将该值减半以获得组件的 X 位置。

然后我对高度使用相同的方法。

由于 titleIconObject 是使用类似的方法定位的，因此我怀疑是否存在会影响定位的样式。

---

您尝试时遇到的问题是 titleIconObject 被放入自定义命名空间 mx_internal 中。这是 Flex 团队的一个黑魔法。但是，要访问该自定义命名空间中的属性，您必须导入命名空间并使用它。更新后的代码应该可以工作：

package com.mysite.components
{
    import mx.containers.Panel;
    import mx.core.mx_internal;    

    use namespace mx_internal;
    public class CenterTitleIconPanel extends Panel
    {

        override protected function layoutChrome(unscaledWidth:Number, unscaledHeight:Number):void {
            super.layoutChrome(unscaledWidth,unscaledHeight);
                if (titleIconObject)
                {
                    titleIconObject.move((unscaledWidth-titleIconObject.width)/2,(unscaledHeight-titleIconObject.height)/2);
                }
        }


        public function CenterTitleIconPanel()
        {
            super();
        }

    }
}

mx_internal 是 Fl​​ex 团队不想记录的所有内容生效（或失效）的地方。