AS3：自定义事件传播

Question

我正在尝试将一系列外部加载的 swf 放在一起投影仪，我的一般问题将尽可能简短。

如果加载到 ctrl 的外部 swf（创作期间放置在舞台上的 MovieClip 实例）的第一帧和最后一帧：

 dispatchEvent(new Event("FIRST_FRAME")); // in the first frame, and: 
 dispatchEvent(new Event("LAST_FRAME")); // in the last frame 

那么 - 是否应该在 ctrl 容器内“听到”这些事件？目前

，我似乎只能监听加载内容中的那些事件，而不是“更高”，我的意思是 - 如果我在加载器完整监听器中说：

mc:MovieClip = MovieClip(e.currentTarget.content);
mc.addEventListener("LAST_FRAME", function(){ // something });

那么会听到事件，但当我说时则不会：

ctrl.addEventListener("LAST_FRAME", function(){ // something });

后者似乎更强大，因此我正在努力让它发挥作用，但我想我错过了一些课程;-) 有人经历过这个吗？我的方法正确还是应该采取另一条路？

大家干杯。

Answer 1

通过在分派事件时将 bubbles 选项设置为 true，您可以让 crtl 显示对象接收从外部 swf 分派的事件。查看以下示例，其中 SWFB.swf 加载到 SWFA.swf：

SWFB:

package swfb
{
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.TimerEvent;
    import flash.utils.Timer;

    public class Main extends Sprite 
    {
        public function Main():void 
        {
            if (stage) init();
            else addEventListener(Event.ADDED_TO_STAGE, init);

        }// end function

        private function init(e:Event = null):void 
        {
            removeEventListener(Event.ADDED_TO_STAGE, init);

            const SECOND:int = 1000;

            var timer:Timer = new Timer(5 * SECOND, 1);
            timer.addEventListener(TimerEvent.TIMER_COMPLETE, onTimerComplete);
            timer.start();

        }// end function

        private function onTimerComplete(e:TimerEvent):void
        {
            dispatchEvent(new TimerEvent(TimerEvent.TIMER_COMPLETE, true, true));

        }// end function

    }// end class

}// end package

SWFA:

package swfa
{
    import flash.display.Loader;
    import flash.display.LoaderInfo;
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.TimerEvent;
    import flash.net.URLRequest;

    public class Main extends Sprite 
    {
        public function Main():void 
        {
            if (stage) init();
            else addEventListener(Event.ADDED_TO_STAGE, init);

        }// end function

        private function init(e:Event = null):void 
        {
            removeEventListener(Event.ADDED_TO_STAGE, init);

            var loader:Loader = new Loader();
            loader.contentLoaderInfo.addEventListener(Event.COMPLETE, onLoaderComplete);
            loader.load(new URLRequest("swf/SWFB.swf"));


        }// end function

        private function onLoaderComplete(e:Event):void
        {
            var loaderInfo:LoaderInfo = LoaderInfo(e.target);

            var container:Sprite = new Sprite();
            container.addChild(loaderInfo.content);
            container.addEventListener(TimerEvent.TIMER_COMPLETE, onContainerTimerComplete);
            addChild(container);

        }// end function

        private function onContainerTimerComplete(e:TimerEvent):void
        {
            trace("TIMER COMPLETE!");

            e.stopPropagation();

        }// end function

    }// end class

}// end package

SWFB.swf 在添加到舞台后 5 秒调度 Timer 事件。当它调度事件时，气泡和可取消选项设置为 true。

在 SWFA.swf 中，SWFB.swf 被加载到其中，然后添加到名为 container 的显示对象容器中。然后，向容器添加一个事件侦听器，用于侦听要调度的 SWFB.swf 中的 Timer 事件。当它被调度时，onContainerTimerComplete() 事件处理程序会调用 Timer 事件的 stopPropagation() 方法来（如其名称所示）停止事件的传播。