XSLT，向生成的 xml 文件的根节点添加属性

Question

我使用 xslt 将两个 xml 文件添加在一起，然后生成的 xml 文件应符合架构。我可以将两个 xml 文件添加在一起，但结果应该在根元素中具有 noNamespaceSchemaLocation="file:///osba.xsd" ass 属性。

这是我的 .xsl 文件：

<?xml version="1.0" encoding="ISO-8859-1"?>
<xsl:transform version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="ISO-8859-1" indent="yes" />
<xsl:variable name="with" select="'reception.xml'" />

<xsl:template match="@*|node()" >
  <xsl:copy>
    <xsl:apply-templates select="@*|node()" />
  </xsl:copy>
</xsl:template>

<xsl:template match="bd">
 <xsl:copy>
  <xsl:apply-templates select="@*|node()" />
  <xsl:variable name="info" select="document($with)/reception/bd[title=current()/title]/." />
  <xsl:for-each select="$info/*">
    <xsl:if test="name()!='title'">
      <xsl:copy-of select="." />
    </xsl:if>
  </xsl:for-each>
 </xsl:copy>
</xsl:template>
</xsl:transform>

我想添加如下内容：

<xsl:template match="/*" >
  <xsl:attribute name="noNamespaceSchemaLocation"><![CDATA[file:///I:/IMY%20Project/XML%20Files/osba.xsd]]></xsl:attribute>
<xsl:apply-templates/>                          

我还没有找到任何方法来匹配当前元素是否为根，我还在考虑是否可以在第一个 xsl:template 中放置 xsl:if test="root" 类型的处理。

感谢您的帮助

Answer 1

像这样的东西：

    <xsl:template match="/*">
        <xsl:element name="{local-name(.)}" namespace="{namespace-uri(.)}">
            <xsl:copy-of select="@*"/>
            <xsl:attribute name="noNamespaceSchemaLocation"
                namespace="http://www.w3.org/2001/XMLSchema-instance">your-value</xsl:attribute>
            <xsl:apply-templates/>
        </xsl:element>
    </xsl:template>