XSLT 属性中的最后一个位置

Question

我需要检查具有特定属性的节点是否是循环中的最后一个，并相应地在最后一个节点之前插入和符号。我尝试使用

<xsl:if test="position() = last()">

似乎没有考虑属性值。

XML

<creators and-others="no">
            <creator type="personal">Roche, R.L.</creator> 
            <creator type="personal">Moulin, D.</creator> 
            <creator type="personal">James, K.</creator> 
            <creator type="affiliation">CEA Centre d'Etudes Nucleaires de Saclay, 91 - Gif-sur-  zYvette (France). Dept. d'Etudes Mecaniques et Thermiques</creator> 
</creators>

这是我需要输出的 ，如：Roche, RL, Moulin, D., & James, K.

另外，有没有办法获取属性为“personal”的“creator”节点的值计数？

Answer 1

为什么不计算匹配模板中的以下兄弟姐妹？同级节点之后的最后一个计数 creator[@type='personal'] 节点将为零。

XSLT 2.0 在 Saxon-HE 9.2.1.1J 下测试（也在 MSXSL 4.0 上作为 XSLT 1.0

<xsl:stylesheet version="2.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    >

    <xsl:output method="text"/>

    <xsl:template match="/creators">
        <xsl:apply-templates select="creator"/>
    </xsl:template>

    <xsl:template match="creator[@type='personal']">
        <xsl:choose>
            <xsl:when test="count(following-sibling::creator[@type='personal'])=0">
                <xsl:text>& </xsl:text><xsl:value-of select="."/>
            </xsl:when>
            <xsl:otherwise>
                <xsl:value-of select="."/><xsl:text>, </xsl:text>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>

    <xsl:template match="creator"/>

</xsl:stylesheet>

工作 ）根据您的输入，产生：

Roche, R.L., Moulin, D., & James, K.

---

根据模板上下文，您始终可以使用 axis 来获取节点的计数。示例：

<xsl:template match="/creators">
    <xsl:variable name="count" select="count(child::creator[@type='personal'])"/>
</xsl:template>

将 $count 设置为 3。

Answer 2

您可以尝试迭代 并使用您的 那里。 XPath 应选择所有这些元素，其中属性 type 的值为 personal。

您可以在 count 函数中使用类似的表达式。

Answer 3

这应该可行

  <xsl:if test="count(//creator[@type='personal']) > 0">
    Found personal
  </xsl:if>

如果您想将其存储在变量中，

<xsl:variable name="PersonalCount" select="count(//creator[@type='personal'])"></xsl:variable>

Answer 4

使用谓词 [@type='personal'] 仅选择所需的 元素。然后，您的测试条件无需使用任何计数或引用同级元素即可工作。您还应该测试是否只有一个 ，否则您最终会输出一个额外的 & 或逗号。因此， 在这里比单独的 更方便。

下面的示例代码。您还可以使用 而不是为 creator 使用单独的模板并调用 如果您想在现有模板中执行此操作。

<?xml version="1.0"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:output method="text"/>

<xsl:template match="creators">
    <xsl:apply-templates select="creator[@type='personal']"/>
</xsl:template>

<xsl:template match="creator">
        <xsl:choose>
            <xsl:when test="position() = 1">
            </xsl:when>
            <xsl:when test="position() = last()">
                <xsl:text> & </xsl:text>
            </xsl:when>
            <xsl:otherwise>
                <xsl:text>, </xsl:text>
            </xsl:otherwise>
        </xsl:choose>
        <xsl:value-of select="."/>
</xsl:template>

</xsl:stylesheet>

给定输入，

<creators and-others="no">
            <creator type="personal">Roche, R.L.</creator>
            <creator type="personal">Moulin, D.</creator>
            <creator type="personal">James, K.</creator>
            <creator type="affiliation">CEA Centre d'Etudes Nucleaires de Saclay, 91 - Gif-sur-  zYvette (France). Dept. d'Etudes Mecaniques et Thermiques</creator>
</creators>

它会产生以下输出

Roche, R.L., Moulin, D. & James, K.

Answer 5

这是一个更短的解决方案，根本不使用任何 XSLT 条件指令：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output method="text"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="/*">
   <xsl:apply-templates select="creator[@type='personal']"/>
 </xsl:template>

 <xsl:template match=
  "creator[@type='personal'][position()>1 and not(position()=last())]">
  <xsl:text>, </xsl:text>
  <xsl:apply-templates/>
 </xsl:template>

 <xsl:template match="creator[@type='personal'][position()=last()]">
  <xsl:text>, & </xsl:text>
  <xsl:apply-templates/>
 </xsl:template>
</xsl:stylesheet>

当应用于提供的 XML 文档时：

<creators and-others="no">
    <creator type="personal">Roche, R.L.</creator>
    <creator type="personal">Moulin, D.</creator>
    <creator type="personal">James, K.</creator>
    <creator type="affiliation">CEA Centre d'Etudes Nucleaires de Saclay, 91 - Gif-sur-  zYvette (France). Dept. d'Etudes Mecaniques et Thermiques</creator>
</creators>

生成所需的正确结果：

Roche, R.L., Moulin, D., & James, K.

另外，有没有办法获得计数
“创建者”节点的值，其中
属性“个人”？

使用：

count(/*/creator[@type='personal'])

说明：

1. 使用模式匹配代替 XSLT 条件指令。

2. 利用 XSLT（默认）处理模型和内置模板。