Haskell (haskeline) 单词补全

Question

Haskeline 使获得文件名制表符补全功能变得非常容易：

module Main where

import System.Console.Haskeline
import System.Environment

mySettings :: Settings IO
mySettings = defaultSettings {historyFile = Just "myhist"}

main :: IO ()
main = do
        args <- getArgs
        let inputFunc = getInputLine
        runInputT mySettings $ withInterrupt $ loop inputFunc 0
    where
        loop inputFunc n = do
            minput <-  handleInterrupt (return (Just "Caught interrupted"))
                        $ inputFunc (show n ++ ":")
            case minput of
                Nothing -> return ()
                Just s -> do
                            outputStrLn ("line " ++ show n ++ ":" ++ s)
                            loop inputFunc (n+1)

它还提供了诸如completeWord和completeQuotedWord之类的函数，这些函数应该能够以与使用completeFilename来实现上述功能相同的方式使用。
（换句话说，基于单词列表（例如函数名称）进行制表符补全，而不是基于文件夹的内容）

任何人都可以提供一个工作示例或工作代码吗？

其他包（如 HCL）中的函数推荐也很有帮助。

Answer 1

这就是你所追求的东西吗？

import Data.List

wordList = [ "Apple", "Pear", "Peach", "Grape", "Grapefruit", "Slime Mold"]

searchFunc :: String -> [Completion]
searchFunc str = map simpleCompletion $ filter (str `isPrefixOf`) wordList

mySettings :: Settings IO
mySettings = Settings { historyFile = Just "myhist"
                      , complete = completeWord Nothing " \t" $ return . searchFunc
                      , autoAddHistory = True
                      }

将代码段中的 mySettings 的定义替换为该定义，它应该可以工作。