Delphi的属性语言特性可以注释哪些语言元素？

Question

Delphi 2010 引入了可以添加到类型声明和方法中的自定义属性。自定义属性可以用于哪些语言元素？

到目前为止我找到的例子包括类声明、字段和方法。 （据我所知通用类不支持自定义属性）。

本文中显示了一些示例。看起来变量（任何类声明外部的）也可以有属性。

根据本文，属性可用于

• 类和记录字段以及方法方法
• 参数
• 属性
• 非局部枚举声明
• 非局部变量声明

是否还有其他可以放置属性的语言元素？

---

更新：本文表明自定义属性可以放置在属性之前： http://francois-piette.blogspot.de/2013/01/using-custom-attribute-for-data.html

它包含此代码示例：

type
  TConfig = class(TComponent)
  public
    [PersistAs('Config', 'Version', '1.0')]
    Version : String;
    [PersistAs('Config', 'Description', 'No description')]
    Description : String;
    FTest : Integer;
    // No attribute => not persistent
    Count : Integer;
    [PersistAs('Config', 'Test', '0')]
    property Test : Integer read FTest write FTest;
  end;

---

我想还有一种阅读方法方法参数上的属性，例如

procedure Request([FormParam] AUsername: string; [FormParam] APassword: string);

Answer 1

有趣的问题！您可以在几乎任何东西上声明属性，问题是使用 RTTI 检索它们。以下是声明自定义属性的快速控制台演示：

• 枚举
• 函数类型
• 过程类型
• 方法类型（对象的）
• 别名类型
• 记录类型
• 类类型
• 类内部的记录类型
• 记录字段
• 记录方法
• 类实例字段
• 类class 字段 (class var)
• 类方法
• 全局变量
• 全局函数
• 局部变量

没有找到为 property 声明自定义属性的方法一堂课。但自定义属性可以附加到 getter 或 setter 方法。

代码，代码之后故事继续：

program Project25;

{$APPTYPE CONSOLE}

uses
  Rtti;

type
  TestAttribute = class(TCustomAttribute);

  [TestAttribute] TEnum = (first, second, third);
  [TestAttribute] TFunc = function: Integer;
  [TestAttribute] TEvent = procedure of object;
  [TestAttribute] AliasInteger = Integer;

  [TestAttribute] ARecord = record
    x:Integer;
    [TestAttribute] RecordField: Integer;
    [TestAttribute] procedure DummyProc;
  end;

  [TestAttribute] AClass = class
  strict private
    type [TestAttribute] InnerType = record y:Integer; end;
  private
    [TestAttribute]
    function GetTest: Integer;
  public
    [TestAttribute] x: Integer;
    [TestAttribute] class var z: Integer;
    // Can't find a way to declare attribute for property!
    property Test:Integer read GetTest;
    [TestAttribute] class function ClassFuncTest:Integer;
  end;

var [TestAttribute] GlobalVar: Integer;

[TestAttribute]
procedure GlobalFunction;
var [TestAttribute] LocalVar: Integer;
begin
end;

{ ARecord }

procedure ARecord.DummyProc;
begin
end;

{ AClass }

class function AClass.ClassFuncTest: Integer;
begin
end;

function AClass.GetTest: Integer;
begin
end;

begin
end.

麻烦在于检索那些自定义属性。查看 rtti.pas 单元，可以检索以下自定义属性：

• 记录类型 (TRttiRecordType)
• 实例类型 (TRttiInstanceType)
• 方法类型 (< code>TRttiMethodType)
• 指针类型 (TRttiPointerType) - 它的用途是什么？
• 过程类型 (TRttiProcedureType)

无法检索“单元”级别或局部变量和过程的任何类型的 RTTI，因此无法检索有关属性的信息。