缩放容器不会影响子容器的宽度

Question

我有一个容器（精灵），其中添加了子元素（精灵）。 当我缩放容器时，我想获得子级的新宽度，但是当我追踪子级的宽度时，我总是得到原始尺寸，即使所有内容都在视觉上按其应有的比例缩放。 如何覆盖children-width？

更新： 我刚刚发现children.graphics-“dimensions”可能导致了这个问题。当我离开图形时，一切似乎都很好。是否可以与子精灵同时缩放图形？

Answer 1

您可以使用 DisplayObject.transform.pixelBounds.width 或 DisplayObject.transform.pixelBounds.height 获取子显示对象的宽度和高度，如下所示：

package 
{
    import flash.display.Sprite;
    import flash.events.Event;

    public class Main extends Sprite 
    {
        public function Main():void 
        {
            if (stage) init();
            else addEventListener(Event.ADDED_TO_STAGE, init);

        }// end function

        private function init(e:Event = null):void 
        {
            removeEventListener(Event.ADDED_TO_STAGE, init);

            var squaresXml:XML = 

            <squares>
                <square name="redSquare" color="0xFF0000" />
                <square name="blueSquare" color="0x00FF00" />
                <square name="greenSquare" color="0x0000FF" />
            </squares>;

            var size:Number = 100;

            var squares:Sprite = new Sprite();

            for (var i:uint = 0; i < squaresXml.children().length(); i++)
            {
                var square:Square = new Square(squaresXml.square[i].@color, size);
                square.name = squaresXml.square[i].@name;
                square.x = i * size;
                squares.addChild(square);

            }// end for

            addChild(squares);

            squares.scaleX = squares.scaleY = 2;

            var redSquare:Square = squares.getChildByName("redSquare") as Square;
            trace(redSquare.width); // output: 100
            trace(redSquare.transform.pixelBounds.width); // output : 200;

        }// end function

    }// end class

}// end package

import flash.display.Shape;
import flash.display.Sprite;

internal class Square extends Shape
{
    public function Square(color:uint, size:Number)
    {
        graphics.beginFill(color);
        graphics.drawRect(0, 0, size, size);
        graphics.endFill();

    }// end function

}// end class

DisplayObject.transform.pixelBounds 基本上获取“一个定义舞台上显示对象的边界矩形的 Rectangle 对象”。

Answer 2

子级宽度始终是原始的全尺寸值。如果你想获得它们的当前宽度，只需将该值乘以容器的缩放比例即可。

例如，如果您的子宽度为 100 像素，并且您将容器缩放到一半大小：100 像素 * 0.5 = 50 像素。或者使用代码：actualChildWidth = container.scaleX * child.width;

Answer 3

我还建议使用显示对象转换的concatenatedMatrix。这将返回一个二维变换矩阵乘以对象的父链到根级别。

获得生成的 Matrix 对象后，您可以检查其 a 或 d 属性以分别查看其根级 x 和 y 缩放因子。