XML 到 XML xsl 样式表

Question

我的任务是研究使用 xsl 来更新工作中的一些 xml 文档，并且我一直在查看一些 xsl 教程，尽管我还没有遇到我理想中想要寻找的内容。 由于我不在工作，

这是我正在寻找的一个小例子：

<?xml version="1.0" encoding="UTF-8"?>
<application>
    <id>627</id>
    <name>application1</name>
    <url>www.application.com</url>
</application>

我需要将其转换为：

<?xml version="1.0" encoding="UTF-8"?>
<application>
    <id>627</id>
    <application_name>application1</application_name>
    <url>www.application.com</url>
</application>

现​​在从我看到的示例和教程中，我可以使用硬编码的 xsl 表来完成此操作，如下所示：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    version="1.0">
    <xsl:output method="xml" encoding="UTF-8"/>
    <xsl:template match="/">
        <application>
        <xsl:apply-templates/>
        </application>
    </xsl:template> 
    <xsl:template match="id">
        <id>
        <xsl:value-of select="id"/>
        <xsl:apply-templates/>
        </id>
     </xsl:template>
     <xsl:template match="name">
        <application_name>
        <xsl:value-of select="name"/>
        <xsl:apply-templates/>
        </application_name>
     </xsl:template>
     <xsl:template match="url">
        <url>
        <xsl:value-of select="url"/>
        <xsl:apply-templates/>
        </url>
     </xsl:template>
</xsl:stylesheet>

但这确实不切实际，因为我们有近 50 个不同的 xml 文档可能需要更改，所以我真的在寻找一个可以使用的包罗万象的模板，然后只覆盖需要更改的适当元素。

xsl中有这个功能吗？

Answer 1

让我看看我是否了解您的需求。下面转换中的第一个模板规则称为身份转换，通过复制来处理所有节点，并且可以针对单个元素、属性、注释、处理指令或文本进行覆盖节点。在你的例子中，我刚刚覆盖了元素name。

---

XSLT 1.0 在 Saxon 6.5.5 下测试

<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output omit-xml-declaration="yes" indent="yes"/>
    <xsl:strip-space elements="*"/>

    <xsl:template match="node()|@*">
        <xsl:copy>
            <xsl:apply-templates select="node()|@*"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="name">
        <xsl:variable name="parent" select="name(parent::*[1])"/>
        <xsl:variable name="node" select="local-name()"/>
        <xsl:element name="{$parent}_{$node}">
            <xsl:apply-templates select="node()|@*"/>
        </xsl:element>
    </xsl:template>

</xsl:stylesheet>

应用于此输入：

<?xml version="1.0" encoding="UTF-8"?>
<anyapplication>
    <id>627</id>
    <name>application1</name>
    <url>www.application.com</url>
</anyapplication>

产生：

<?xml version="1.0" encoding="UTF-8"?>
<anyapplication>
    <id>627</id>
    <anyapplication_name>application1</anyapplication_name>
    <url>www.application.com</url>
</anyapplication>

Answer 2

你可以尝试这样的事情：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    version="1.0">
     <xsl:template match="name">
        <application_name>
        <xsl:value-of select="name"/>
        <xsl:apply-templates/>
        </application_name>
     </xsl:template>
     <xsl:template match="not(name)">
        <xsl:copy-of select="."/>
        <xsl:apply-templates/>
     </xsl:template>
</xsl:stylesheet>