Actionscript 3，拖动时旋转对象

Question

我有一个需要通过单击和拖动来旋转的对象。按照一些 AS2 代码，每次单击鼠标时，我都会让对象旋转一点，但无法使其与拖动一起工作。

needle.addEventListener(MouseEvent.MOUSE_DOWN, fl_ClickToDrag_2);
stage.addEventListener(MouseEvent.MOUSE_UP, fl_ReleaseToDrop_2);

function fl_ClickToDrag_2(event:MouseEvent):void
{

        var angle = Math.atan2(mouseY-needle.y,mouseX-needle.x);
        // apply rotation to handle by converting angle into degrees
        needle.rotation = angle*180/Math.PI;
        // rotate the grip opposite the handle so it won't rotate along with it
        //this.grip._rotation = -this._rotation;
}

function fl_ReleaseToDrop_2(event:MouseEvent):void
{
    needle.stopDrag();
}

Answer 1

我看到的问题是 MOUSE_DOWN 事件每次点击仅触发一次，因此您只需在处理程序中运行代码一次。

可能有比这更好的方法，但这就是我考虑这样做的方式：

编辑详细信息：

public class Test extends MovieClip {
    private var n:Needle;

    public function Test() {
        // constructor code
        n = new Needle();

        stage.addEventListener(MouseEvent.MOUSE_DOWN,mouseDownF,false,0,true);
        stage.addEventListener(MouseEvent.MOUSE_UP,mouseUpF,false,0,true);


        n.x = stage.stageWidth/2; //center needle on stage
        n.y = stage.stageHeight/2;
        addChild(n); //add needle to stage
    }
    public function mouseDownF(e:MouseEvent):void {
        stage.addEventListener(MouseEvent.MOUSE_MOVE,rotate,false,0,true);
    }
    public function rotate(e:MouseEvent):void {
        var angle:Number = Math.atan2(mouseY - n.y,mouseX - n.x); //get angle in radians (pythagoras) 

        angle = angle * 180/Math.PI -90; //convert to degrees , the 90 is to have it point to the mouse

        n.rotation = angle; //rotate
    }
    public function mouseUpF(e:MouseEvent):void {
        stage.removeEventListener(MouseEvent.MOUSE_MOVE,rotate);
    }
}

因此，当用户单击（mouseDown）时，它会激活一个触发 的事件侦听器每次鼠标移动时旋转 处理程序。当用户松开单击时，事件侦听器将被销毁。添加事件监听器时的 false,0,true); 是使其成为 弱引用侦听器，以便它被垃圾收集器收集，而不会永远坐在内存中占用空间。