如何指示 Perl 将在特定字符上断开的多行视为单行？

Question

例如，我有一个 txt 文件，其中多行调用在 & 符号上断开。

command1

command2

execute myscript &
        opt1=val1 &
        opt2=val2

...

打开文件时，有没有办法告诉 Perl 将这三行视为一行并忽略 & ？

Answer 1

打开文件时没有。但在阅读时加入他们并不难：

open(my $in, '<', 'file.txt') or die;
while (<$in>) {
  $_ .= <$in> while s/&\s*\z//;

  # $_ now contains a complete record
  ...
}

Answer 2

如果记录之间总是有多个换行符，请考虑使用记录分隔符来读取它们。然后，您可以快速检查 &，并执行拆分/连接：

use English '-no_match_vars'; 

sub read_records {
    local $RS = "\n\n";  # or,  for the machoistic,  $/ works too without English
    ... # open the file
    while (my $record = <$fh>) {
        chomp $record;               # uses $RS for what to remove, nice!
        if ($record =~ /&\s*$/ms) {  # & at the end of *any* line (w/only spaces)
            $record = join ' ', split /\s*&\s+/, $record; # pull them out
        }
        ... # do something with the record
    }
}

Answer 3

我假设您的输入具有合理的大小，因此将整个内容读入标量，清理它，然后处理更友好的结果。

#! /usr/bin/env perl

use strict;
use warnings;

sub read_input {
  my($fh) = @_;
  local $/;
  scalar <$fh>;
}

my $commands = read_input \*DATA;

$commands =~ s/&\n//g;
print $commands;

__DATA__
command1

command2

execute myscript &
        opt1=val1 &
        opt2=val2

输出：

command1

command2

execute myscript         opt1=val1         opt2=val2