Office 2011 for Mac 中的 VBA Shell 函数

Question

我正在尝试从 Word 2011 for Mac 中的 VBA 宏启动 shell 脚本，该脚本将在终端窗口中运行。我尝试过使用 Shell 函数和 MacScript 函数，但 VBA 解释器似乎在这两种情况下都无法找到脚本。

根据 VBA 参考文档，以下内容应该有效：

 RetVal = Shell("Macintosh HD:Applications:Calculator.app", vbNormalFocus)

这会产生运行时错误 53“找不到文件”。

有什么建议吗？

Answer 1

Mac 上的 Shell() VBA 函数似乎需要完整路径作为 HFS 样式路径（使用冒号而不是斜杠）。它似乎也不像 Windows 上那样接受参数（如果添加任何参数，则会报告“找不到路径”错误）。

还可以使用 MacScript() VBA 函数：MacScript("do shell script ""command""")。这可能是最简单的选择，也是我建议做的。缺点是它有相当大的开销（每次调用 100-200 毫秒）。

另一种替代方法是标准 C 库中的 system() 函数：

Private Declare Function system Lib "libc.dylib" (ByVal command As String) As Long

Sub RunSafari()
    Dim result As Long
    result = system("open -a Safari --args http://www.google.com")
    Debug.Print Str(result)
End Sub

请参阅 http://pubs.opengroup.org/onlinepubs/009604499/functions/system.html 查看文档。

system() 仅返回退出代码。如果您想获取命令的输出，可以使用popen()。

Private Declare Function popen Lib "libc.dylib" (ByVal command As String, ByVal mode As String) As Long
Private Declare Function pclose Lib "libc.dylib" (ByVal file As Long) As Long
Private Declare Function fread Lib "libc.dylib" (ByVal outStr As String, ByVal size As Long, ByVal items As Long, ByVal stream As Long) As Long
Private Declare Function feof Lib "libc.dylib" (ByVal file As Long) As Long

Function execShell(command As String, Optional ByRef exitCode As Long) As String
    Dim file As Long
    file = popen(command, "r")

    If file = 0 Then
        Exit Function
    End If

    While feof(file) = 0
        Dim chunk As String
        Dim read As Long
        chunk = Space(50)
        read = fread(chunk, 1, Len(chunk) - 1, file)
        If read > 0 Then
            chunk = Left$(chunk, read)
            execShell = execShell & chunk
        End If
    Wend

    exitCode = pclose(file)
End Function

Sub RunTest()
    Dim result As String
    Dim exitCode As Long
    result = execShell("echo Hello World", exitCode)
    Debug.Print "Result: """ & result & """"
    Debug.Print "Exit Code: " & str(exitCode)
End Sub

请注意，上例中的几个 Long 参数是指针，因此如果发布了 64 位版本的 Mac Word，则必须对其进行更改。

Answer 2

希望您现在已经找到答案，但您只需要完整路径：

RetVal = Shell("Macintosh HD:Applications:Calculator.app:" & _
              "Contents:MacOS:Calculator", vbNormalFocus)

另一个示例如下：

RetVal = Shell("Macintosh HD:Users:brownj:Documents:" & _
              "rnaseq:IGV_2.0.14:igv.sh", vbNormalFocus)

Answer 3

另一个问题完全是这样的：由于 AppleScript 环境和用户的 bash 环境之间的差异，权限会导致您的脚本失败。这个问答帮助我解决了这个问题。为了让我的脚本正常工作，我必须解决一些路径和权限问题（不是脚本本身，而是脚本涉及的内容）。

以下是我的建议，希望在您进行故障排除时能够比我在使用 AppleScript 编辑器之前看到的毫无意义的 Excel 错误提供更好的见解：

1. 使用 AppleScript 编辑器确认该脚本实际上可以作为任何用户以及任何环境变量运行。使用：

   1. 在 Spotlight 中，开始输入“applescript editor”，直到它出现，然后单击它
   2. 创建新的 AppleScript 编辑器文件

   3. 将您的简单脚本输入到新文件中，不使用双引号 - 我的读法是

      执行 shell 脚本“parseCsvAndOpen.sh”
      

   4. 点击脚本的“运行”按钮
   5. 跟踪任何问题，进行更改，然后重复点击“运行”按钮，直到它在 AppleScript 编辑器中执行
      • 好消息是，如果您需要返回 StackOverflow 或 Google 寻求帮助，您的搜索范围会更窄；-)

2. 现在将您的简单脚本从 AppleScript 编辑器复制到您的 vba 并确认它仍然有效 < /p>

   1. 我可以将双引号加倍，并将其放在 MacScript 代码后面的双引号中：

      MacScript“执行shell脚本”“parseCsvAndOpen.sh”“”
      

      这确实是一个、两个、然后三个双引号字符！ （大概是转义双引号）

Answer 4

对于使用 64 位 Office 的任何人，这里有 Robert 的代码，已更新为与 32 位和 64 位版本兼容。请注意，由于沙箱的更改，声明中必须使用 libc 的完整路径，否则您将在从未有版本的 OSX/Office 上出现错误 53“找不到文件”。

#If Mac Then
  #If VBA7 Then
    ' 64 bit Office:mac
    Private Declare PtrSafe Function popen Lib "/usr/lib/libc.dylib" (ByVal command As String, ByVal mode As String) As LongPtr
    Private Declare PtrSafe Function pclose Lib "/usr/lib/libc.dylib" (ByVal file As LongPtr) As Long
    Private Declare PtrSafe Function fread Lib "/usr/lib/libc.dylib" (ByVal outStr As String, ByVal size As LongPtr, ByVal items As LongPtr, ByVal stream As LongPtr) As Long
    Private Declare PtrSafe Function feof Lib "/usr/lib/libc.dylib" (ByVal file As LongPtr) As LongPtr
    Private file As LongPtr
  #Else
    ' 32 bit Office:mac
    Private Declare Function popen Lib "libc.dylib" (ByVal command As String, ByVal mode As String) As Long
    Private Declare Function pclose Lib "libc.dylib" (ByVal file As Long) As Long
    Private Declare Function fread Lib "libc.dylib" (ByVal outStr As String, ByVal size As Long, ByVal items As Long, ByVal stream As Long) As Long
    Private Declare Function feof Lib "libc.dylib" (ByVal file As Long) As Long
    Private file As Long
  #End If

  Public Function execShell(command As String, Optional ByRef exitCode As Long) As String
    file = popen(command, "r")
    
    If file = 0 Then
      Exit Function
    End If
    
    While feof(file) = 0
      Dim chunk As String
      Dim read As Long
      chunk = SPACE(50)
      read = fread(chunk, 1, Len(chunk) - 1, file)
      If read > 0 Then
        chunk = Left$(chunk, read)
        execShell = execShell & chunk
      End If
    Wend
    
    exitCode = pclose(file) ' 0 = success
  End Function

#End If

Answer 5

只是没有足够的点数来发表评论，但感觉这是对罗宾·奈特答案的补充。当然，功劳仍然归于他。
对于 Excel 15.18 (2015)，标准 C 库的 system() 函数中使用的 open 调用不需要 --args关键字不再：

Private Declare Function system Lib "libc.dylib" (ByVal command As String) As Long

Sub RunSafari()
    Dim result As Long
    result = system("open -a Safari http://www.google.com")
    Debug.Print Str(result)
End Sub

这很好用。 2011年没有测试过。