使用POST方法将数据从Flash发送到PHP

Question

我开发了一个应用程序，允许用户在画布上绘制简单的图像。影片剪辑（画布）的名称是canvas_mc。

我需要使用 php 将这张图保存在服务器上。我必须将影片剪辑（canvas_mc）转换为png和jpeg并保存。我已使用 http://www.flashandmath 中提供的一些类成功将其保存在本地驱动器上

。 com/advanced/smoothdraw/index.html

如何使用 PHP 将其保存在服务器上。我被要求使用 post 方法。如果可能的话，也给我代码，因为我刚刚从设计转向编程:-)

Answer 1

不确定如何将图像转换为数据等，但我有一个类，您可以使用它将数据传输到 PHP 脚本（可以从那里将数据插入数据库）。

package
{
    import flash.net.URLRequest;
    import flash.net.URLLoader;
    import flash.net.URLVariables;
    import flash.net.URLRequestMethod;
    import flash.events.Event;

    /**
     * @author Marty Wallace
     * @version 1.00
     */
    public class PHPData extends Object
    {
        /**
         * Sends data to a PHP script
         * @param script A URL to the PHP script
         */
        public function send(script:String, vars:URLVariables):void
        {
            var req:URLRequest = new URLRequest(script);

            req.data = vars;
            req.method = URLRequestMethod.POST;

            var loader:URLLoader = new URLLoader();
            loader.load(req);

            // listeners
            loader.addEventListener(Event.COMPLETE, _complete);
        }

        /**
         * Called when a response has been received from a PHP script
         * @param e Event.COMPLETE
         */
        private function _complete(e:Event):void
        {
            var vars:URLVariables = new URLVariables(e.target.data);

            var i:String;
            for(i in vars)
            {
                trace(i + ": " + vars[i]);
            }

            e.target.removeEventListener(Event.COMPLETE, _complete);
        }
    }
}

使用：

var php:PHPData = new PHPData();
var vars:URLVariables = new URLVariables();

vars.imagedata = your_image_data;

php.send("your_php_script.php", vars);