VBA：将文本文件中的行复制到 Word 文档中

Question

通常我创建宏时会记录该功能，然后相应地调整它们，因此不幸的是，我不知道如何实现此操作。

我有许多文本文件，它们是帐户档案；每个文件至少有 30k+ 行，每个文件中有数百个甚至数千个帐户。文档中的第一行包含帐号，每个帐户都由唯一的文本字符串分隔。

目标是有一个宏在文本文件中查找，找到帐号，然后复制其下面的所有行，直到到达唯一的分隔字符串，并将它们粘贴到活动 Word 文档中以供查看。

我不认为我会从这样一个模糊的问题中得到具体的答案，但任何可以提供的指示将不胜感激。

Answer 1

这是一个快速&肮脏的一个来说明原理......让文本文件被称为“accounts.txt”并包含以下内容：

Account 1
item 1
item 2
item 3
=========
Account 2
item 4
item 5
=========
Account 3
item 6
item 7
=========

现在让我们看一些使用 Open As 和 的非常基本的 VBA 代码>行输入和循环构造....

Sub GetAccountFromTextFile(FileName As String, Accnt As String)
Dim MyLine As String, State As String

    Open FileName For Input As #1
    State = "Searching"               ' we could make this much simpler but 
                                      ' want to illustrate the different stati
                                      ' the loop is reaching

    Do While Not (EOF(1) Or State = "End")

        Line Input #1, MyLine         ' read next line from text file

                                      ' now process as function of
                                      ' content and current state

        If State = "Reading" And MyLine = "=========" Then
            State = "End"

        ElseIf MyLine = "Account " & Accnt Then
            Selection.InsertAfter "Account " & Accnt & vbCrLf
            State = "Reading"

        ElseIf State = "Reading" Then
            Selection.InsertAfter MyLine & vbCrLf
        End If

    Loop
    Close #1

End Sub

您可以通过另一个子 Start test() 从 Word 文档中的任何位置调用它

Sub test()
    GetAccountFromTextFile "C:\Documents and Settings\MySelf\Desktop\accounts.txt", 1
    GetAccountFromTextFile "C:\Documents and Settings\MySelf\Desktop\accounts.txt", 3
    GetAccountFromTextFile "C:\Documents and Settings\MySelf\Desktop\accounts.txt", 2
End Sub

，并且以下内容将被粘贴到文档中：

Account 1
item 1
item 2
item 3
Account 3
item 6
item 7
Account 2
item 4
item 5

现在您可以在您的关于如何获取文件名和的主要子部分（可能是对话框形式）在调用帐户 getter 之前，您需要修改帐号的条件以及 getter 中的分隔模式。不是很复杂，但应该足以让你继续下去。

祝你好运
迈克·D