使用 Prolog DCG 分割字符串

Question

我正在尝试使用 DCG 将字符串拆分为用空格分隔的两部分。例如“abc def”应该给我返回“abc”和“abc def”。 “定义”。该计划& DCG如下。

main:-
    prompt(_, ''),
    repeat,
    read_line_to_codes(current_input, Codes),
    (
        Codes = end_of_file
    ->
        true
    ;
        processData(Codes),
        fail
    ).

processData(Codes):-
    (
        phrase(data(Part1, Part2), Codes)
    ->
        format('~s, ~s\n', [ Part1, Part2 ])
    ;
        format('Didn''t recognize data.\n')
    ).

data([ P1 | Part1 ], [ P2 | Part2 ]) --> [ P1 | Part1 ], spaces(_), [ P2 | Part2 ].
spaces([ S | S1 ]) --> [ S ], { code_type(S, space) }, (spaces(S1); "").

这工作正常。但我发现必须输入 [ P1 |第 1 部分] & <代码>[ P2 |第 2 部分] 确实很冗长。因此，我尝试替换 [ P1 | 的所有实例第 1 部分] w/ 第 1 部分 &同样w/ [ P2 | Part2]中data的定义，即如下。

data(Part1, Part2) --> Part1, spaces(_), Part2.

这更容易输入，但这给了我一个 Arguments are not充分实例化 错误。因此，看起来未绑定的变量不会自动解释为 DCG 中的代码列表。有没有其他方法可以让这个不那么冗长？我的目的是在其他编程语言中使用正则表达式的地方使用 DCG。

Answer 1

你的直觉是正确的； DCG 的术语扩展过程（至少在 SWI-Prolog 中，但应该适用于其他）与您修改后的 data 版本给出以下内容：

?- listing(data). 

data(A, D, B, F) :-
    phrase(A, B, C),
    spaces(_, C, E),
    phrase(D, E, F).

如您所见，变量 Part1< DCG 规则的 /code> 和 Part2 部分已被解释为再次调用 phrase/3，而不是列表；您需要明确指定它们是列表，以便将它们视为列表。

我可以建议一个更通用的替代版本。考虑以下一组 DCG 规则：

data([A|As]) --> 
    spaces(_), 
    chars([X|Xs]), 
    {atom_codes(A, [X|Xs])}, 
    spaces(_), 
    data(As).
data([]) --> [].

chars([X|Xs]) --> char(X), !, chars(Xs).
chars([]) --> [].

spaces([X|Xs]) --> space(X), !, spaces(Xs).
spaces([]) --> [].

space(X) --> [X], {code_type(X, space)}. 
char(X) --> [X], {\+ code_type(X, space)}.

看一下顶部的第一个子句； data 规则现在尝试匹配 0 到多个空格（由于剪切而尽可能多），然后匹配一对多非空格字符来构造一个原子 (A）从代码中，然后再次0到多空格，然后递归以在字符串中找到更多原子（As）。你最终得到的是一个原子列表，它出现在输入字符串中，没有任何空格。您可以通过以下方式将此版本合并到您的代码中：

processData(Codes) :-
    % convert the list of codes to a list of code lists of words
    (phrase(data(AtomList), Codes) ->
        % concatenate the atoms into a single one delimited by commas
        concat_atom(AtomList, ', ', Atoms),
        write_ln(Atoms)
    ;
        format('Didn''t recognize data.\n')
    ).

此版本将字符串分开，单词之间有任意数量的空格，即使它们出现在字符串的开头和结尾。