如何获取加密数据的大小？

Question

我有一个棘手的问题，希望我能很好地解释它， 我想从 Windows 注册表中读取由另一个程序保存的值，但我没有其来源，但我已经知道该值的类型，如下所示：

  _MyData = record
    byteType: Byte;
    encData: PByte;
  end;

byteType 指示该值的类型数据为整数（1,2,3…），您可以忘记这个参数，而encData是使用Windows crypt32.dll函数（CryptProtectData）加密的数据 我使用下面的代码从注册表中读取值：

procedure TForm1.Button2Click(Sender: TObject);
var
  myData: _MyData;
  reg: TRegistry;
  valueSize: Integer;
begin
  reg := TRegistry.Create;
  try
    if reg.OpenKey(KEY_PATH,false) then
      Begin
        valueSize := reg.GetDataSize(VALUE_NAME);
        reg.ReadBinaryData(VALUE_NAME, myData, valueSize);
      End;
  finally
    reg.Free;
  end;
end;

// KEY_PATH, VALUE_NAME are string Consts。

因此，现在我在 myData.encData 中有加密数据，现在我想通过将其传递给具有以下签名的 CryptUnprotectData 函数来解密它：

function CryptUnprotectData(pDataIn: PDATA_BLOB; ppszDataDescr: PLPWSTR; pOptionalEntropy: PDATA_BLOB; pvReserved: Pointer; pPromptStruct: PCRYPTPROTECT_PROMPTSTRUCT; dwFlags: DWORD; pDataOut: PDATA_BLOB): BOOL; stdcall;

首先，我需要将加密数据放入 DATA_BLOB 类型的变量中它具有以下结构：

  _CRYPTOAPI_BLOB = record
    cbData: DWORD;
    pbData: PBYTE;
  end;
  DATA_BLOB = _CRYPTOAPI_BLOB;
  PDATA_BLOB = ^DATA_BLOB;

pbData是指向加密数据的指针（我从注册表中读取它），cbData是加密数据的大小，这是我的问题我在 myData.encData 中有指向加密数据的指针（我已经从注册表中读取了它），它是 PByte，但我不知道如何获取该数据的大小？如果我没有给函数CryptUnprotectData正确的大小，它总是在输出中给出nil，知道如何做到这一点吗？

感谢您的帮助。

编辑：解决方案，感谢 Ken Bourassa

  _MyData = packed record
    byteType: Byte;
    encData: array of byte;
  end;

procedure TForm1.Button2Click(Sender: TObject);
var
  myData: ^_MyData;
  reg: TRegistry;
  valueSize: Integer;
  dataIn, dataOut: DATA_BLOB;
begin
  reg := TRegistry.Create;
  try
    if reg.OpenKey(KEY_PATH,false) then
      Begin
        valueSize := reg.GetDataSize(VALUE_NAME);
        GetMem(myData, ValueSize);
        try
          reg.ReadBinaryData(VALUE_NAME, myData^, valueSize);

          dataOut.cbData := 0;
          dataOut.pbData := nil;
          dataIn.cbData := Valuesize - SizeOf(Byte);
          dataIn.pbData := @myData.encData;
          CryptUnprotectData(@dataIn,nil,nil,nil,nil,CRYPTPROTECT_UI_FORBIDDEN,@dataOut);

          //yes, it works, Thank you very much Ken Bourassa


        finally
          FreeMem(myData);
        End;
      End;
  finally
    reg.Free;
  end;

end;

Answer 1

数据的大小是 reg.GetDataSize - SizeOf(Byte)

但这现在是您唯一的问题，

您的 _MyData 结构有 8 个字节长。因此，当您调用

reg.ReadBinaryData(VALUE_NAME, myData, valueSize); 

任何超过 8 个字节的键值时，就会发生缓冲区溢出。即使您读取的密钥短于 8 个字节，EncData 也会包含垃圾。

我宁愿这样做：

_MyData = packed record              
  byteType: Byte;              
  encData: array[0..MaxInt] of byte;            
end    

procedure TForm1.Button2Click(Sender: TObject);    
var      
  myData: ^_MyData;
  reg: TRegistry;      
  valueSize: Integer;    
begin      
  reg := TRegistry.Create;      
  try        
    if reg.OpenKey(KEY_PATH,false) then          
    Begin            
      valueSize := reg.GetDataSize(VALUE_NAME);            
      GetMem(MyData, ValueSize);
      try
        reg.ReadBinaryData(VALUE_NAME, myData^, valueSize); 
        //Do what is needed with MyData. The size of MyData.EncData = Valuesize - SizeOf(Byte)
      finally
        FreeMem(MyData);
      end;

    End;      
  finally        
    reg.Free;      
  end;    
end;

我将 packed 关键字添加到记录定义中，因为我相信这是最可能的声明方式......但是，这一切都取决于以下规范：应用程序写入值。我还将 EncData 声明为 Array[0..MaxInt] of byte。这使得声明 _MyData 类型的变量成为一个非常糟糕的主意，但这是我所知道的允许记录中的变量数组而不强制禁用范围检查的唯一方法。如果在您的项目中始终使用 Range Checking = False 运行并不需要担心（或者您不介意在代码中需要的地方打开/关闭它），您可以将其声明为 Array[0..0] of字节。我知道它应该有效，但我不知道该方法的具体细节，因为我从未真正使用过它。

编辑（被接受后）：

实际上，将 EncData 声明为 字节数组 与将其声明为 PByte 一样糟糕。 字节数组 是一个引用类型（实际上是一个 4 字节指针）。如果您尝试在代码中访问 EncByte[0]，您很可能会收到反病毒病毒。它起作用的唯一原因是您只使用 @myData.encData （事实上记录是使用 GetMem 分配的）。但是像这样使用，您可以像这样声明 EncData ：

_MyData = packed record              
  byteType: Byte;              
  encData: Record end;            
end    

这仍然有效，因为在您的示例中，您并不真正关心声明的 EncData 类型，您只关心它所在的内存地址。

Answer 2

我觉得很奇怪，第二个字段是“PByte”值。它存储一个指针吗？只要进程正在运行，指针就有效，除非它在程序运行时仅存储临时值（如果是这样，那就是奇怪的选择）。或者它存储了该值指向的任意长度的缓冲区？如果它首先存储类型值，然后存储缓冲区，则缓冲区大小只是 ValueSize - SizeOf(Byte)，除非记录未打包并且直接从内存“转储”，否则可能会有一些填充字节。