如何使用 xsl 将 xml 中的一个标签替换为另一个标签

Question

我的 xml 文件如下所示。

<rule>  
  <name>86</name>
  <ruleId>100</ruleId>
  <ruleVersion>1.0</ruleVersion>
  <brlVersion>1.0</brlVersion>
</rule>

我需要将 name 替换为 brlName，并且需要添加另一个标签作为 drlName。输出应如下所示。

<rule>  
  <brlName>86</brlName>
  <ruleId>100</ruleId>
  <ruleVersion>1.0</ruleVersion>
  <brlVersion>1.0</brlVersion>
  <drlName>86_1.0</drlName>
</rule>

请帮助我使用相应的 xsl 以获得所需的输出。 感谢您的帮助！

Answer 1

这是身份转换的典型任务（下面转换中的第一个模板规则）。只有两个覆盖（最后两个规则）。

---

XSLT 1.0 在 Saxon 6.5.5 下测试

<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output omit-xml-declaration="yes" indent="yes"/>
    <xsl:strip-space elements="*"/>

    <xsl:template match="node()|@*">
        <xsl:copy>
            <xsl:apply-templates select="node()|@*"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="name">
        <brlName><xsl:value-of select="."/></brlName>
    </xsl:template>

    <xsl:template match="brlVersion">
        <xsl:copy-of select="."/>
        <drlName><xsl:value-of select="preceding-sibling::name"/>_1.0</drlName>
    </xsl:template>

</xsl:stylesheet>

Answer 2

此转换：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="node()|@*" name="identity">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match="name">
  <brlName><xsl:apply-templates select="node()|@*"/></brlName>
 </xsl:template>

 <xsl:template match="/*/*[last()]">
  <xsl:call-template name="identity"/>
   <drlName>86_1.0</drlName>
 </xsl:template>
</xsl:stylesheet>

应用于提供的 XML 文档时：

<rule>
    <name>86</name>
    <ruleId>100</ruleId>
    <ruleVersion>1.0</ruleVersion>
    <brlVersion>1.0</brlVersion>
</rule>

产生所需的正确结果：

<rule>
   <brlName>86</brlName>
   <ruleId>100</ruleId>
   <ruleVersion>1.0</ruleVersion>
   <brlVersion>1.0</brlVersion>
   <drlName>86_1.0</drlName>
</rule>

说明：

1. 使用和覆盖身份规则/模板——最基本、最强大的XSLT 设计模式。

2. 覆盖任何名为 name 的元素并创建名为 brlName 的元素（重命名）。

3. 覆盖顶部元素的最后一个子元素。按此节点的名称调用身份规则（复制），然后根据要求创建一个名为 drlName 的元素，其中包含特定的文本节点子节点。

使用和覆盖身份规则/模板是最基本、最强大的 XSLT 设计模式。您可以在此处了解更多信息。