一个 PChar 变量的 GetMem 更改其他 PChar 变量的内容

Question

所以，我有以下问题。我有 2 个 PChar 变量。我首先分配内存，执行一些操作，为第二个变量分配内存 - 在这一步中，第一个变量包含错误值（我在调试时看到它）。这是代码：

procedure TReadThread.Execute;
Var
  iRead, temp, i, count : Integer;
  header, params : PChar;
begin
  try
    GetMem(header, 12);
    iRead := recv(FSocket, header^, 12, 0);

    if (iRead<>12) then
      raise Exception.Create('Header recieving problem!');

    temp := StrToIntDef(String(copy(header,3,4)),0);

    if (temp=0) then
      raise Exception.Create('Body receiving problem!');

    count := temp*SizeOf(Char);

    if (count+12<=16384) then
      begin
        GetMem(params, count);
        iRead := recv(FSocket, params^, count, 0);

        if (iRead<>count) then
          raise Exception.Create('Cant recieve messsage fully!');
      end
    else
      raise Exception.Create('Bad message size (>16 KB)!');

    GetMem(FText, temp*SizeOf(Char)+12);
    FText := PChar(String(header) + String(params));

    FreeMem(header);
    FreeMem(params);
  except
    on E : Exception do
      ShowMessage(E.Message);
  end;
end;

在线

iRead := recv(FSocket, params^, count, 0);

当我寻找变量 HEADER 值时 - 我看到了一些令人惊奇的东西 - 与我在程序开始时看到的不一样。我该如何修复它？

Answer 1

我认为 FText 是一个 PChar。既然您说您使用的是 Delphi 2010，那么您应该知道 Char 实际上与 WideChar 同义，并且宽度为 2 个字节。我怀疑您确实想使用 AnsiChar。

最明显的问题是您为 FText 分配内存，然后通过对 FText 的分配将其丢弃。此外，当程序结束时，FText 引用的内存也会被销毁。

我认为您应该执行以下操作：

• 切换到 AnsiChar 进行 recv 调用。
• 将 FText 更改为 AnsiString。
• 完全停止使用 GetMem 并使用堆栈分配。

也许是这样的：

procedure TReadThread.Execute;
Var
  iRead, count: Integer;
  header: array [0..12-1] of AnsiChar;
  params: array [0..16384-1] of AnsiChar;
begin
  try
    iRead := recv(FSocket, header, 12, 0);

    if (iRead<>12) then
      raise Exception.Create('Header receiving problem!');

    count := StrToIntDef(Copy(header,3,4),0);

    if (count=0) then
      raise Exception.Create('Body receiving problem!');

    if (count+12<=16384) then
      begin
        iRead := recv(FSocket, params, count, 0);
        if (iRead<>count) then
          raise Exception.Create('Cant receive messsage fully!');
      end
    else
      raise Exception.Create('Bad message size (>16 KB)!');

    SetLength(FText, 12+count);
    Move(header, FText[1], 12);
    Move(params, FText[13], count);
  except
    on E : Exception do
      ShowMessage(E.Message);
  end;
end;

Answer 2

正如大卫·赫弗南之前所说。 Char 是 2 个字节，pChar 在 Delphi 2010 中也指向 Unicode 字符。但是 David 的代码有 2 个问题

1. 如果你想获取国际字符（unicode 或 utf8 字符串），你不能使用 AnsiChar

2. 如果将 params 变量定义为数组AnsiChar 的 [0..16384-1] 那么你将失去程序性能。局部变量将使用堆栈并像 David 那样定义参数，这将消耗您的堆栈空间。

对于答案，您可以通过 1 个简单的更改来使用您的代码。仅将标头和参数变量定义为 PAnsiChar。其他代码不变即可。

标头，参数：PAnsiChar；