QML 中的图像圆角

Question

令我惊讶的是，Image 组件没有 radius 属性。我尝试通过将图像放入圆角矩形中来模拟圆角，但它不会剪切角。

Rectangle {
    anchors.right: rectContentBg.left
    anchors.top: rectContentBg.top
    anchors.margins: 8

    radius: 8

    width: 64
    height: 64

    Image {
        id: imgAuthor

        opacity: 1
        smooth: false

        anchors.fill: parent

        source: "qrc:/res/sample_avatar.jpg"
    }
}

如何正确创建带有圆角的图像？

Answer 1

由于 QtGraphicalEffects 模块，从 Qt 5 开始就存在内置的官方解决方案，我很惊讶地发现没有人提供如此简单的解决方案。如果您的目标是 Qt 6.x，不幸的是，QtGraphicalEffects 已被弃用，因此请跳转到答案的第二部分，该部分提出了独立于 QtGraphicalEffects 的解决方案。

QtGraphicalEffects 解决方案

在其他效果中，OpacityMask 是用于此目的的类型。这个想法是用一个具有正确设置的半径的矩形来掩盖源Image。 是使用 分层 的最简单示例：

Image {
    id: img
    property bool rounded: true
    property bool adapt: true

    layer.enabled: rounded
    layer.effect: OpacityMask {
        maskSource: Item {
            width: img.width
            height: img.height
            Rectangle {
                anchors.centerIn: parent
                width: img.adapt ? img.width : Math.min(img.width, img.height)
                height: img.adapt ? img.height : width
                radius: Math.min(width, height)
            }
        }
    }
}

这 最少的代码可以为方形图像产生很好的结果，但是
它还通过 adapt 变量考虑非方形图像。通过将标志设置为false，无论图像大小如何，生成的蒙版将始终是圆形。这是可能的，因为使用了外部 Item，它填充源并允许随意调整真实掩码（内部 矩形）的大小。 如果您只是瞄准填充源的遮罩，而不管其纵横比如何，您显然可以摆脱外部Item。。

这是一张可爱的猫图像，其格式为方形（左），带有 adapt: true 的非方形格式（中心），最后是非方形格式和 adapt: false (right):

此解决方案的实现细节与基于着色器的答案非常相似在另一个好的答案中（参见OpacityMask的QML源代码，可以找到< a href="http://ftp.fau.de/qtproject/ministro/android/qt5/objects/5.1014-x86/qml/QtGraphicalEffects/OpacityMask.qml" rel="noreferrer">此处 - SourceProxy 只是返回一个格式良好的 ShaderEffectSource 来提供效果）。

无依赖解决方案

如果您不想 - 或不能 - 依赖于 QtGraphicalEffects 模块（好吧，依赖于 OpacityMask.qml< /code> 实际上），您可以使用着色器重新实现效果。除了已经提供的解决方案之外，另一种方法是使用 step，smoothstep 和 fwidth 函数。这是代码：

import QtQuick 2.5

Image {
    id: image

    property bool rounded: true
    property bool adapt: true

    layer.enabled: rounded
    layer.effect: ShaderEffect {
        property real adjustX: image.adapt ? Math.max(width / height, 1) : 1
        property real adjustY: image.adapt ? Math.max(1 / (width / height), 1) : 1

        fragmentShader: "
        #ifdef GL_ES
            precision lowp float;
        #endif // GL_ES
        varying highp vec2 qt_TexCoord0;
        uniform highp float qt_Opacity;
        uniform lowp sampler2D source;
        uniform lowp float adjustX;
        uniform lowp float adjustY;

        void main(void) {
            lowp float x, y;
            x = (qt_TexCoord0.x - 0.5) * adjustX;
            y = (qt_TexCoord0.y - 0.5) * adjustY;
            float delta = adjustX != 1.0 ? fwidth(y) / 2.0 : fwidth(x) / 2.0;
            gl_FragColor = texture2D(source, qt_TexCoord0).rgba
                * step(x * x + y * y, 0.25)
                * smoothstep((x * x + y * y) , 0.25 + delta, 0.25)
                * qt_Opacity;
        }"
    }
}

与第一种方法类似，添加了 rounded 和 adapt 属性来控制效果的视觉外观，如上所述。

Answer 2

这段代码可以帮助你

Rectangle {
    width: 200
    height: 200

    color: "transparent"

    //this Rectangle is needed to keep the source image's fillMode
    Rectangle {
        id: imageSource

        anchors.fill: parent
        Image {
            anchors.fill: parent
            source: "your_image_file_path"

            fillMode: Image.PreserveAspectCrop
        }
        visible: false

        layer.enabled: true
    }

    Rectangle {
        id: maskLayer
        anchors.fill: parent
        radius: parent.width / 2

        color: "red"

        border.color: "black"

        layer.enabled: true
        layer.samplerName: "maskSource"
        layer.effect: ShaderEffect {

            property var colorSource: imageSource
            fragmentShader: "
                uniform lowp sampler2D colorSource;
                uniform lowp sampler2D maskSource;
                uniform lowp float qt_Opacity;
                varying highp vec2 qt_TexCoord0;
                void main() {
                    gl_FragColor =
                        texture2D(colorSource, qt_TexCoord0)
                        * texture2D(maskSource, qt_TexCoord0).a
                        * qt_Opacity;
                }
            "
        }

    }

    // only draw border line
    Rectangle {
        anchors.fill: parent

        radius: parent.width / 2

        border.color: "black"
        border.width: 2

        color: "transparent"
    }
}

Answer 3

当您的背景是纯色或从不移动图像时，制作圆角的一种快速方法是将您的 Image 与另一个图像（或与 BorderImage) 只绘制角点。

如果这不是一个选项，但您正在使用 OpenGL，则另一种方法是通过像素着色器将遮罩应用于图像。请参阅http://blog.qt.digia .com/blog/2011/05/03/qml-shadereffectitem-on-qgraphicsview/ 用于在 Qt 4 之上工作的插件。

最后，还可以编写 QDeclarativeImageProvider 对图像进行预处理以使角变圆。

Answer 4

虽然接受的答案和 来自 @fury 的答案对我来说同样有效（Qt 5.9.3），但他们都离开了当应用于光栅图像时，角落会出现一些像差（SVG 中没有）。在所有情况下对我来说最有效的是将OpacityMask应用于周围的项目，例如原始帖子中的矩形。

Rectangle {
    id: root;
    anchors.right: rectContentBg.left
    anchors.top: rectContentBg.top
    anchors.margins: 8

    radius: 8

    width: 64
    height: 64

    // apply rounded corners mask
    layer.enabled: true
    layer.effect: OpacityMask {
        maskSource: Rectangle {
            x: root.x; y: root.y
            width: root.width
            height: root.height
            radius: root.radius
        }
    }

    Image {
        id: imgAuthor
        opacity: 1
        smooth: false
        anchors.fill: parent
        source: "qrc:/res/sample_avatar.jpg"
    }
}

Answer 5

如果您有单色背景，则可以在顶部绘制圆角矩形的边框。

Image{
    id:img
}
Rectangle { // rounded corners for img
    anchors.fill: img
    color: "transparent"
    border.color: "blue" // color of background
    border.width: 4
    radius: 4
}

Answer 6

QML 目前仅支持矩形裁剪，但您可能想看看 qt-components 项目中的 DeclarativeMaskedImage：

http://qt.gitorious.org/qt-components/qt-components/blobs/master/src/symbian/sdeclarativemaskedimage.h

Answer 7

我知道我来晚了一点，但我通过谷歌搜索来到这里，所以我想我会帮助后代:) QtGraphicalEffects OpacityMask 应该更简单地做到这一点（我对图层效果方法有疑问）

Image {
    id: imgAuthor

    width: 64
    height: 64

    source: "qrc:/res/sample_avatar.jpg"

    visible: false // this is needed or the corners of the image will be visible underneath the opacity mask
}

OpacityMask {
    anchors.fill: imgAuthor
    source: imgAuthor
    maskSource: Rectangle {
        width: imgAuthor.width
        height: imgAuthor.height
        radius: 8
        visible: false // this also needs to be invisible or it will cover up the image
    }
}

Answer 8

如果您有单色背景，则可以在顶部绘制圆角矩形的边框。

Item {
    property int radius: 0
    property color bgColor: "#000000"
    property int drawRadius: radius > 0 ? radius : width/2

    Image {
        anchors.fill: parent
        sourceSize: Qt.size(width, height)
        asynchronous: true
    }

    Canvas {
        anchors.fill: parent
        antialiasing: true
        onPaint: {
            var ctx = getContext("2d")
            ctx.fillStyle = bgColor
            ctx.beginPath()
            ctx.rect(0, 0, width, height)
            ctx.fill()

            ctx.beginPath()
            ctx.globalCompositeOperation = 'source-out'
            ctx.roundedRect(0, 0, width, height, drawRadius, drawRadius)
            ctx.fill()
        }
    }
}