使用 ModalResult 退出表单

Question

我有一堆表单，我想将它们自动化，以便它们可以自行打开和关闭。

我知道如何打开它们（通过 OnActivate 函数），但我在关闭它们时遇到问题。

例如，我有

procedure TProgressForm.FormActivate(Sender: TObject);
begin
  inherited;
  if FModItem.IsInQueue then
    begin
      RunBtnClick(Self);
      ModalResult := mrOK;
    end;    
end;

一个运行函数。我想在函数运行后关闭窗口，这就是 ModalResult 应该做的。

（我还尝试在 RunBtnClick 过程的最后添加 ModalResult 行，但这也不起作用）

并且我正在创建这样的表单：

ProgForm := TProgressForm.Create(Self, FModItem);
Self.Visible := False;
try
 if ProgForm.ShowModal = mrOK then
  begin
    Left := ProgForm.Left;
    Top := ProgForm.Top;
  end;

我已经能够创建按钮来关闭表单通过将 mrOK 添加到对象检查器中的模态结果中，但我似乎无法明确执行此操作

有人能明白为什么它不起作用吗？

谢谢

Answer 1

不起作用的原因是，在显示表单之后、开始检查对 ModalResult 的更改之前，VCL 在 TCustomForm.ShowModal 中主动将 ModalResult 设置为 0。所以在 OnActivate 和 OnShow 中，你太早了。

解决方案是延迟通知。这可以通过 PostMessage 来完成，如下所示：

const
  UM_ACTIVATED = WM_USER + 1;

type
  TProgressForm = class(TForm)
    procedure FormActivate(Sender: TObject);
  private
    procedure UMActivated(var Message: TMessage); message UM_ACTIVATED;
  end;

...

procedure TProgressForm.FormActivate(Sender: TObject);
begin
  PostMessage(Handle, UM_ACTIVATED, 0, 0);
end;

procedure TProgressForm.UMActivated(var Message: TMessage);
begin
  { Your code here }
  ModalResult := mrOk;
end;

来源：NLDelphi< /a>

Answer 2

我将重写 ShowModal 并执行您现在在 OnActvate 中执行的测试。这有两大优点：

• 如果不需要显示，则根本不显示表单。从 OnActivate 启动表单关闭会导致表单在屏幕上“闪烁”：它会显示并立即关闭。
• 不依赖于不受您控制的代码。您不再关心祖先 ShowModal 中的操作顺序，因为只有在需要实际显示表单时才调用它。

当然，以这种方式使用 GUI 元素（表单）有点代码味道，因为它基本上使用 GUI 而不需要用户交互。毫无疑问，可以将其重构为使用一个中间函数，该函数返回 mrOk 并执行 RunBtnClick() 的操作，而无需 GUI，并创建 Form仅在需要时。我想这是一种成本效益的情况。

代码：

TMyForm = class(TForm)
....
public
  function ShowModal:Integer;override;
end;

function TMyForm.ShowModal:Integer;
begin
  if FModItem.IsInQueue then
    begin
      RunBtnClick(Self);
      Result := mrOK;
    end
  else
    Result := inherited ShowModal;
end;

Answer 3

OnActivate 事件在 TCustomForm.ShowModal 中的 ModalResult 重置为 mrNone 之前触发。这意味着 OnActivate 处理程序中的 ModalResult 更改将被忽略。

  function TCustomForm.ShowModal: Integer;
  Show;
  try
    SendMessage(Handle, CM_ACTIVATE, 0, 0);  << Your onActivate is called here
    ModalResult := 0; << ModalResult is reset

Answer 4

查看 TCustomForm.ShowModal（在 forms.pas 内）：直到发送 CM_ACTIVATE 消息之后（所述消息触发您的 OnActivate 调用），才首先检查 ModalResult；事实上，在 OnActivate 调用返回后，它立即设置为 0，因此您的作业不起作用也就不足为奇了。

我不想对此搞得太混乱（您的代码肯定无法通过气味测试），但您可以尝试添加类似以下内容：

if ModalResult=0 then 
     SendMessage(Handle, CM_ACTIVATE, 0, 0);

到事件处理程序的顶部。