Flex：监听来自parentApplication的customEvent

Question

我正在尝试监听在 Spark 弹出窗口中创建的事件。目的是在弹出窗口中发送和更新数组，以便在弹出窗口关闭时由调用应用程序接收。

正如下面内联评论的那样，我已经测试过它达到了在 popUp 中调度事件的点，并且从未在主应用程序中被监听。我缺少什么？

我的自定义事件如下：

package folder1
{           
import flash.events.Event;
import mx.collections.ArrayCollection;

public class MyCustomEvent extends Event
{
    public var myDataToPass:ArrayCollection;
    public static const ON_SUBMIT:String = "submit";

    public function MyCustomEvent (type:String, bubbles:Boolean=true, cancelable:Boolean=false)
    {
        super(type, bubbles, cancelable);
    }
 }
}

在 PopUp 中，在tileWindow 中我有

public var newEvent:MyCustomEvent=new MyCustomEvent("submit");
        private function closePopUp():void{

            newEvent.myDataToPass=elementData;
            dispatchEvent(newEvent);
            trace(" came into close function"); //this is tested
            PopUpManager.removePopUp(this);

        }

最后在调用应用程序中我有这个结构

private function createModifyPopUp(evt:MouseEvent):void{
            var modify:Modify=new Modify();
            modify.elementData=elements;
            modify.eventTarget=evt.currentTarget;
            addEventListener(MyCustomEvent.ON_SUBMIT,rebuild);

            trace("came  into modify"); //this is tested
            PopUpManager.addPopUp(modify,this,true);
            PopUpManager.centerPopUp(modify);
        }



        private function rebuild(evt:MyCustomEvent):void{
            trace("got listened");//NEVER REACHES HERE
            elements=evt.myDataToPass;
            buildfunction(); 
        }  

Answer 1

问题是 Flex 中弹出窗口的父容器不是创建弹出窗口的 Application 或可视组件，而是 SystemManager。因此，如果您想从弹出窗口使用事件冒泡，您应该监听 SystemManager 实例的事件，该实例可通过组件的 systemManager 属性获得。

就我自己而言，我不喜欢在这种情况下使用冒泡，而是订阅弹出窗口事件，直接在 addPopUp 方法中获取指向窗口的链接。

Answer 2

试试这个：

private function createModifyPopUp(evt:MouseEvent):void{
            var modify:Modify=new Modify();
            modify.elementData=elements;
            modify.eventTarget=evt.currentTarget;
            modify.addEventListener(MyCustomEvent.ON_SUBMIT,rebuild);

            trace("came  into modify"); //this is tested
            PopUpManager.addPopUp(modify,this,true);
            PopUpManager.centerPopUp(modify);
        }

您可以在这里找到解决问题的更详细的示例：http://xposuredesign.net/ ?p=53

干杯