XSL如何根据值计算节点数而不使用属性且不区分大小写

Question

我最近开始学习XSL。我想用它来将我的 xml 文件转换为 html 文件。我要提取的数据应该显示有多少节点具有一定的价值。

XML 具有以下结构：

<Tests> 
   <Test> 
        <TestName> a </TestName>  
        <Date> 12.11.10 </Date>       
        <Result> Pass</Result> 
   </Test>   
   <Test> 
       <TestName> b </TestName>      
       <Date> 13.11.10 </Date> 
       <Result> Fail </Result> 
   </Test>
    <Test>
        <TestName> c </TestName>         
        <Date> 14.11.10 </Date>     
        <Result> Pass </Result>   
    </Test>
</Tests> 

对于此 xml，我得到的输出为 --> 2（通过次数） 1（失败次数）

xsl 对于上述 xml::

<xsl:key name="kTestByResult" match="Test" use="normalize-space(Result)"/> 
<xsl:template match="/">         
 <xsl:value-of select="concat(count(key              
 ('kTestByResult','Fail')),' (number of Fails) ',
  count(key'kTestByResult','Pass')),'(number of Passes)')"/>     
 </xsl:template> 

这里通过可能是（通过/通过/通过）。 在任何情况下我都希望结果为 2 Passes。

有什么想法吗？？？

Answer 1

将大写字符转换为小写：

<xsl:variable name="upper-case" select="'ABCDEFGHIJKLMNOPQRSTUVWXYZ'"/>
<xsl:variable name="lower-case" select="'abcdefghijklmnopqrstuvwxyz'"/>

<xsl:key name="kTestByResult" match="Test" use="translate( normalize-space(Result), $upper-case, $lower-case )"/> 

<xsl:template match="/">         
    <xsl:value-of select="concat( 
        count( key('kTestByResult', 'fail') ), ' (number of Fails) ',
        count( key('kTestByResult', 'pass') ), '(number of Passes)'
    )"/>     
</xsl:template> 

Answer 2

试试这个：

<xsl:key name="kTestByResult" match="Test" use="normalize-space(
  translate(Result,
  'qwertyuiopasdfghjklzxcvbnm',
  'QWERTYUIOPASDFGHJKLZXCVBNM'))"/> 

<xsl:template match="/">         
 <xsl:value-of select="concat(
   count(key('kTestByResult','FAIL')),
   ' (number of Fails) ',
   count(key('kTestByResult','PASS')),
   '(number of Passes)')"/>     
 </xsl:template> 

这会将所有值转换为大写，然后将大写“PASS”或“FAIL”传递给关键函数。

Answer 3

这是一个更通用的解决方案，它列出了 Result 的所有不同值的计数，而不对其进行硬编码 - 例如，如果 XML 文档发生更改，结果会被跳过或 INDECISIVE，这些新值也将被列出并计数：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:variable name="vLower" select=
 "'abcdefghijklmnopqrstuvwxyz'"/>

 <xsl:variable name="vUpper" select=
 "'ABCDEFGHIJKLMNOPQRSTUVWXYZ'"/>

 <xsl:key name="kResultByVal" match="Result"
  use="translate(normalize-space(),
                 'abcdefghijklmnopqrstuvwxyz',
                 'ABCDEFGHIJKLMNOPQRSTUVWXYZ')"/>

 <xsl:template match="text()"/>

 <xsl:template match=
  "Result
   [generate-id()
   =
    generate-id(key('kResultByVal',
                     translate(normalize-space(),
                               'abcdefghijklmnopqrstuvwxyz',
                               'ABCDEFGHIJKLMNOPQRSTUVWXYZ'
                               )
                    )[1])
   ]
   ">
   <xsl:text>
</xsl:text>
  <xsl:value-of select="translate(normalize-space(),$vLower,$vUpper)"/>
  <xsl:text>: </xsl:text>
  <xsl:value-of select=
   "count(key('kResultByVal',
              translate(normalize-space(),
                        $vLower,
                        $vUpper
                        )
              )
          )
   "/>
 </xsl:template>
</xsl:stylesheet>

当应用于提供的 XML 文档时：

<Tests>
    <Test>
        <TestName> a </TestName>
        <Date> 12.11.10 </Date>
        <Result> Pass</Result>
    </Test>
    <Test>
        <TestName> b </TestName>
        <Date> 13.11.10 </Date>
        <Result> Fail </Result>
    </Test>
    <Test>
        <TestName> c </TestName>
        <Date> 14.11.10 </Date>
        <Result> Pass </Result>
    </Test>
</Tests>

生成所需的正确结果：

PASS: 2
FAIL: 1

II。产生相同结果的 XSLT 2.0 解决方案：

<xsl:stylesheet version="2.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema">
    <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="/">
     <xsl:for-each-group select="//Result"
                         group-by="normalize-space(upper-case(.))">
      <xsl:sequence select=
      "normalize-space(upper-case(.)),
       count(current-group()),
       '
'
      "/>
     </xsl:for-each-group>
 </xsl:template>
</xsl:stylesheet>