解决枚举上不完整的模式匹配问题

Question

在模式匹配时，是否有任何创造性的方法来解决 .NET 的“弱”枚举？我希望它们的功能与 DU 类似。这是我目前的处理方式。还有更好的想法吗？

[<RequireQualifiedAccess>]
module Enum =
  let unexpected<'a, 'b, 'c when 'a : enum<'b>> (value:'a) : 'c = //'
    failwithf "Unexpected enum member: %A: %A" typeof<'a> value //'

match value with
| ConsoleSpecialKey.ControlC -> ()
| ConsoleSpecialKey.ControlBreak -> ()
| _ -> Enum.unexpected value //without this, gives "incomplete pattern matches" warning

Answer 1

我认为总的来说这是一个艰巨的任务，正是因为枚举是“弱”的。 ConsoleSpecialKey 是“完整”枚举的一个很好的示例，其中分别由 0 和 1 表示的 ControlC 和 ControlBreak 是唯一有意义的它可以承担的价值观。但我们有一个问题，您可以将任何整数强制转换为 ConsoleSpecialKey！：

let x = ConsoleSpecialKey.Parse(typeof<ConsoleSpecialKey>, "32") :?> ConsoleSpecialKey

因此您给出的模式确实不完整，确实需要处理。

（更不用说诸如System.Reflection.BindingFlags之类的更复杂的枚举，它们用于位掩码，但通过类型信息与简单枚举无法区分，这使情况进一步复杂化 编辑：实际上，@ildjarn 指出 Flags 属性按照惯例用于区分完整枚举和位掩码枚举，尽管编译器赢了不能阻止您对未标记此属性的枚举使用按位运算，再次揭示枚举的弱点）。

但是，如果您正在使用像 ConsoleSpecialKey 这样的特定“完整”枚举，并且一直编写最后一个不完整的模式匹配案例真的很困扰您，那么您始终可以创建一个完整的活动模式：

let (|ControlC|ControlBreak|) value =
    match value with
    | ConsoleSpecialKey.ControlC -> ControlC
    | ConsoleSpecialKey.ControlBreak -> ControlBreak
    | _ -> Enum.unexpected value

//complete
match value with
| ControlC -> ()
| ControlBreak -> ()

然而，这类似于简单地不处理不完整的模式匹配情况并抑制警告。我认为你当前的解决方案很好，你只要坚持下去就好了。

Answer 2

根据斯蒂芬在评论中对他的回答提出的建议，我最终得到了以下解决方案。 Enum.unexpected 通过在前一种情况下抛出 FailureException 和 Enum.Unhandled 来区分无效枚举值和未处理的情况（可能是由于稍后添加枚举成员） 在后者中。

[<RequireQualifiedAccess>]
module Enum =

  open System

  exception Unhandled of string

  let isDefined<'a, 'b when 'a : enum<'b>> (value:'a) =
    let (!<) = box >> unbox >> uint64
    let typ = typeof<'a>
    if typ.IsDefined(typeof<FlagsAttribute>, false) then
      ((!< value, System.Enum.GetValues(typ) |> unbox)
      ||> Array.fold (fun n v -> n &&& ~~~(!< v)) = 0UL)
    else Enum.IsDefined(typ, value)

  let unexpected<'a, 'b, 'c when 'a : enum<'b>> (value:'a) : 'c =
    let typ = typeof<'a>
    if isDefined value then raise <| Unhandled(sprintf "Unhandled enum member: %A: %A" typ value)
    else failwithf "Undefined enum member: %A: %A" typ value

示例

type MyEnum =
  | Case1 = 1
  | Case2 = 2

let evalEnum = function
  | MyEnum.Case1 -> printfn "OK"
  | e -> Enum.unexpected e

let test enumValue =
  try 
    evalEnum enumValue
  with
    | Failure _ -> printfn "Not an enum member"
    | Enum.Unhandled _ ->  printfn "Unhandled enum"

test MyEnum.Case1 //OK
test MyEnum.Case2 //Unhandled enum
test (enum 42)    //Not an enum member

显然，它在运行时而不是编译时警告未处理的情况，但这似乎是我们能做的最好的事情。

Answer 3

我认为这是 F# 的一个功能，它迫使您处理枚举的意外值（因为可以通过显式转换来创建它们，并且因为程序集的更高版本可能会添加其他命名值）。你的方法看起来不错。另一种选择是创建一个活动模式：

let (|UnhandledEnum|) (e:'a when 'a : enum<'b>) = 
    failwithf "Unexpected enum member %A:%A" typeof<'a> e

function
| System.ConsoleSpecialKey.ControlC -> ()
| System.ConsoleSpecialKey.ControlBreak -> ()
| UnhandledEnum r -> r

这里与 UnhandledEnum 模式匹配的过程将抛出异常，但返回类型是可变的，因此无论是什么类型，它都可以在模式的右侧使用比赛归来。

Answer 4

这是 F# 语言的一个小烦恼，而不是一个功能。可以创建无效的枚举，但这并不意味着 F# 模式匹配代码必须处理它们。如果由于枚举的值超出了定义范围而导致模式匹配失败，则错误不在模式匹配代码中，而在生成无意义值的代码中。因此，不考虑无效值的枚举上的模式匹配没有任何问题。

想象一下，如果按照相同的逻辑，F# 用户每次遇到 .Net 引用类型（可以为 null，就像枚举可以存储无效整数一样）时都被迫执行 null 检查。语言将变得无法使用。幸运的是，枚举出现得并不多，我们可以用 DU 来替代。

编辑：此问题现已通过 https://github.com/dotnet/fsharp/pull/ 解决4522，取决于用户手动添加#nowarn“104”。您将收到有关未匹配的定义 DU 案例的警告，但如果您已涵盖所有案例，则不会收到警告。