用于在空 xml 标记中设置默认值的 XSLT

Question

我正在某些 xml 上运行 xsl 转换，并且需要能够在一些标记上设置一些默认值（如果它们显示为空）。例如，我的 xml 有

<record>
<name>Bob</name>
<latitude>51.23645</latitude>
<longitude>-0.1254</longitude>
<rank></rank>
</record>

<record>
<name>Chantel</name>
<latitude></latitude>
<longitude></longitude>
<rank>5</rank>
</record>

，我想设置一些默认值来输出：

<record>
<name>Bob</name>
<latitude>51.23645</latitude>
<longitude>-0.1254</longitude>
<rank>0</rank>
</record>

<record>
<name>Chantel</name>
<latitude>0.00</latitude>
<longitude>0.00</longitude>
<rank>5</rank>
</record>

我认为这很简单，但似乎无法破解它。

提前致谢。

编辑：这就是我试图做的。仍在学习，只是在黑暗中摸索！

<xsl:template match="record">
  <xsl:when test="name()='latitude'">
    <xsl:element name="latitude">
      <xsl:choose>
        <xsl:when test="text()=''">
          <latitude>0.00</latitude>
        </xsl:when>
        <xsl:otherwise>
          <xsl:value-of select="latitude"></xsl:value-of>
        </xsl:otherwise>
      </xsl:choose>
    </xsl:element>
  </xsl:when>
</xsl:template>

Answer 1

试试这个：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="1.0">

  <xsl:output method="xml" indent="yes"/>
  <xsl:template match="@*|node()">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
  </xsl:template>
  <xsl:template match="rank[not(text())]">
    <xsl:copy>
      <xsl:apply-templates select="@*"/>
      <xsl:text>0</xsl:text>
    </xsl:copy>
  </xsl:template>
  <xsl:template match="latitude[not(text())]|longitude[not(text())]">
    <xsl:copy>
      <xsl:apply-templates select="@*"/>
      <xsl:text>0.00</xsl:text>
    </xsl:copy>
  </xsl:template>
</xsl:stylesheet>

添加更多模板来设置其他标签的默认值。

工作原理：第一个模板称为“身份模板”，它将节点从输入复制到输出而不更改。第二个模板匹配没有文本子节点的“rank”节点（即空“rank”节点），将它们及其属性复制到输出，然后插入默认值。