Excel VBA函数将数组打印到工作簿

Question

我编写了一个宏，它采用二维数组，并将其“打印”到 Excel 工作簿中的等效单元格。

有没有更优雅的方法来做到这一点？

Sub PrintArray(Data, SheetName, StartRow, StartCol)

    Dim Row As Integer
    Dim Col As Integer

    Row = StartRow

    For i = LBound(Data, 1) To UBound(Data, 1)
        Col = StartCol
        For j = LBound(Data, 2) To UBound(Data, 2)
            Sheets(SheetName).Cells(Row, Col).Value = Data(i, j)
            Col = Col + 1
        Next j
            Row = Row + 1
    Next i

End Sub


Sub Test()

    Dim MyArray(1 To 3, 1 To 3)
    MyArray(1, 1) = 24
    MyArray(1, 2) = 21
    MyArray(1, 3) = 253674
    MyArray(2, 1) = "3/11/1999"
    MyArray(2, 2) = 6.777777777
    MyArray(2, 3) = "Test"
    MyArray(3, 1) = 1345
    MyArray(3, 2) = 42456
    MyArray(3, 3) = 60

    PrintArray MyArray, "Sheet1", 1, 1

End Sub

Answer 1

与其他答案相同的主题，保持简单

Sub PrintArray(Data As Variant, Cl As Range)
    Cl.Resize(UBound(Data, 1), UBound(Data, 2)) = Data
End Sub


Sub Test()
    Dim MyArray() As Variant

    ReDim MyArray(1 To 3, 1 To 3) ' make it flexible

    ' Fill array
    '  ...

    PrintArray MyArray, ActiveWorkbook.Worksheets("Sheet1").[A1]
End Sub

Answer 2

创建一个变量数组（最简单的方法是读取变量变量中的等效范围）。

然后填充数组，并将数组直接赋值给范围。

Dim myArray As Variant

myArray = Range("blahblah")

Range("bingbing") = myArray

变体数组最终将成为二维矩阵。

Answer 3

一种更优雅的方法是一次分配整个数组：

Sub PrintArray(Data, SheetName, StartRow, StartCol)

    Dim Rng As Range

    With Sheets(SheetName)
        Set Rng = .Range(.Cells(StartRow, StartCol), _
            .Cells(UBound(Data, 1) - LBound(Data, 1) + StartRow, _
            UBound(Data, 2) - LBound(Data, 2) + StartCol))
    End With
    Rng.Value2 = Data

End Sub

但要注意：它最多只能处理大约 8,000 个单元格的大小。然后 Excel 抛出一个奇怪的错误。最大大小不是固定的，并且不同的 Excel 安装有很大不同。

Answer 4

正如其他人所建议的，您可以直接将二维数组写入工作表上的范围，但是如果您的数组是一维的，那么您有两个选择：

1. 首先将一维数组转换为二维数组，然后将其打印在工作表上（作为范围）。
2. 将一维数组转换为字符串并将其打印在单个单元格中（作为字符串）。

这是描述这两个选项的示例：

Sub PrintArrayIn1Cell（myArr 作为变体，单元格作为范围）
    单元格=加入（myArr，“，”）
结束子
Sub PrintArrayAsRange(myArr 作为变体，单元格作为范围)
    cell.Resize(UBound(myArr, 1), UBound(myArr, 2)) = myArr
结束子
子 TestPrintArrayIntoSheet() '2dArrayToSheet
    变暗 arr 作为变体
    arr = 分割("ab c", " ")

    '在一个单元格中打印：将所有数组元素打印为以逗号分隔的单个字符串 (a,b,c)：
    PrintArrayIn1Cell arr, [A1]

    '在单独的单元格中打印：要在单独的单元格中打印数组元素：
    Dim arr2D 作为变体
    arr2D = Application.WorksheetFunction.Transpose(arr) '将一维数组转换为二维数组
    PrintArrayAsRange arr2D, Range("B1:B3")
结束子

注意：转置将渲染逐列输出，要获得逐行输出，请再次转置它 - 希望这是有道理的。

华泰

Answer 5

我测试过的版本

Sub PrintArray(RowPrint, ColPrint, ArrayName, WorkSheetName)

Sheets(WorkSheetName).Range(Cells(RowPrint, ColPrint), _
Cells(RowPrint + UBound(ArrayName, 2) - 1, _
ColPrint + UBound(ArrayName, 1) - 1)) = _
WorksheetFunction.Transpose(ArrayName)

End Sub

Answer 6

您可以定义一个 Range、数组的大小并使用它的 value 属性：

Sub PrintArray(Data, SheetName As String, intStartRow As Integer, intStartCol As Integer)

    Dim oWorksheet As Worksheet
    Dim rngCopyTo As Range
    Set oWorksheet = ActiveWorkbook.Worksheets(SheetName)

    ' size of array
    Dim intEndRow As Integer
    Dim intEndCol As Integer
    intEndRow = UBound(Data, 1)
    intEndCol = UBound(Data, 2)

    Set rngCopyTo = oWorksheet.Range(oWorksheet.Cells(intStartRow, intStartCol), oWorksheet.Cells(intEndRow, intEndCol))
    rngCopyTo.Value = Data

End Sub