perl 两个连续的反勾 shell 命令不运行

Question

我正在尝试编写 perl 脚本来管理亚马逊 ec2 实例。在我的部分代码中，我有两个 shell 命令，当我调用它们时，第一个命令运行，但第二个命令不运行。我似乎无法找到一个很好的解释。代码如下：

$run_instances = 'ec2-run-instances ami-8e1fece7 -k mykey -t t1.micro';
$outp = `$run_instances`;
$outp =~ /INSTANCE\s+(i-\w+)\s/;
$instance_id = $1;
$describe_instances = "ec2-describe-instances $instance_id";
$outp = `$describe_instances`;
$outp =~ /(ec2-(\d+-\d+-\d+-\d+).\S+)/;

问题是 $outp 这里有 $run_instances 的输出。有一段时间我不明白为什么我得到了错误的输出；然后我意识到 $describe_instances 命令没有运行。

我查看了从 Linux shell 调用的 $describe_instances 的值，它工作得很好。我从另一个 Perl 脚本调用它，它工作得很好。

然后我给了 $outp 运行 $run_instances 时捕获的输出 ($outp = "INSTANCE ......")。它有效，所以我想到当这两个命令连续运行时，第二个命令不会运行。

还要注意的另一件事是，当每次 $run_instances 工作但 $describe_instances 不工作时，我将上面的代码放入循环中。

如果您能对此提供一些说明，我将非常高兴:)

谢谢

Answer 1

您的程序有一些危险信号。我将在下面讨论它们，并在最后提出一种更好的编写代码的方法。

危险信号 1

您问题中的代码尝试使用反引号执行外部命令并假设成功。您应该始终检查对操作系统的任何调用的状态。失败的 `$command` — 还有称为 qx// 或 readpipe — 以一种或多种方式显示自身，具体取决于是否命令已执行但失败或尝试执行命令是否失败：

• 特殊变量 $? 非零。
• 如果执行失败
  • 特殊变量$! 包含失败的描述。
  • 该运算符在标量上下文中返回未定义的值，在列表上下文中返回空列表。

使用 Perl，`$command` 执行一个子 shell 以便执行 $command，因此子 shell 可能是执行并失败的程序，eg，命令语法错误。

下面示例中的一个命令在我的机器上成功了。

#! /usr/bin/env perl

use strict;
use warnings;

my @commands = (
  "bad syntax (",
  "does-not-exist",
  "/etc/passwd",
  "perl --no-such-option",
  "perl -le 'print q(Hello world)'",
);

foreach my $c (@commands) {
  print "Capturing output of command $c...\n";
  my $output = `$c`;

  if ($? == 0) {
    print "  - command executed successfully!\n";
  }
  elsif ($? == -1) {
    print "  - command failed to execute: \$!=$!\n";
  }
  else {
    print "  - command exited with status " . ($? >> 8) . "\n";
  }

  print "  - value of \$output is ",
        (defined $output ? "" : "un"), "defined\n\n";
}

输出：

Capturing output of command bad syntax (...
sh: Syntax error: "(" unexpected
  - command exited with status 2
  - value of $output is defined

Capturing output of command does-not-exist...
Can't exec "does-not-exist": No such file or directory at ./runcmds line 16.
  - command failed to execute: $!=No such file or directory
  - value of $output is undefined

Capturing output of command /etc/passwd...
Can't exec "/etc/passwd": Permission denied at ./runcmds line 16.
  - command failed to execute: $!=Permission denied
  - value of $output is undefined

Capturing output of command perl --no-such-option...
Unrecognized switch: --no-such-option  (-h will show valid options).
  - command exited with status 29
  - value of $output is defined

Capturing output of command perl -le 'print q(Hello world)'...
  - command executed successfully!
  - value of $output is defined

Red Flag 2

请注意，例如输出行，

Can't exec "does-not-exist": No such file or directory at ./runcmds line 16.

我没有编写生成此警告的代码。相反，它会自动发生，因为我使用 use warnings 行启用了警告编译指示。如果您启用了警告，Perl 至少已经给您提供了有关问题原因的提示，因此我假设您没有启用警告。

这是另一个危险信号。警告可以帮助您。始终为任何重要的程序启用它们。

危险信号 3

最后，您无条件地使用正则表达式捕获变量 $1，当匹配失败并且您从不同的匹配中获取捕获的值时，这种习惯将导致令人惊讶的错误。您应该始终将 $1、$2 和朋友的使用包装在条件（eg）内，

if (/pa(tte)rn/) {
  do_something_with $1;
}

建议的修复

位于代码顶部附近，紧接在 行，

use warnings;

shebang 行，您应该立即添加我也推荐的

use strict;

但这可能需要更多工作来清理您的代码。我们随时帮助您理解并克服在这一有价值的努力中发现的任何问题。

使用下面的 output_of 捕获命令的输出或通过适当的诊断来终止。

sub output_of {
  my($cmd) = @_;
  my $output = `$cmd`;
  return $output if $? == 0;

  if ($? == -1) {
    die "$0: $cmd failed to execute: $!\n";
  }
  elsif ($? & 127) {
    my $signal = $? & 127;
    my $core = ($? & 128) ? ", core dumped" : "";
    die "$0: $cmd died with signal $signal$core\n";
  }
  else {
    die "$0: $cmd exited with status " . ($? >> 8) . "\n";
  }
}

您问题中的代码部分变为

my $output;
$output = output_of 'ec2-run-instances ami-8e1fece7 -k mykey -t t1.micro';
if ($output =~ /INSTANCE\s+(i-\w+)\s/) {
  my $instance_id = $1;

  $output = output_of "ec2-describe-instances $instance_id";
  if ($output =~ /(ec2-(\d+-\d+-\d+-\d+).\S+)/) {
    print "$0: found instance $2\n";  # or whatever
  }
  else {
    die "$0: no ec2-IP in ec2-describe-instances output:\n$output";
  }
}
else {
  die "$0: no INSTANCE in ec2-run-instances output:\n$output";
}

通过这些更改，您的代码将为处理 ec2-run-instances 和 ec2-describe-instances 的输出中的所有故障模式提供标准错误诊断 而不是让你想知道出了什么问题。

Answer 2

在以下内容之后 $outp 是已定义还是未定义：

$outp = `$describe_instances`;

您是否已验证 $instance_id 设置为您期望的值？
$的值是多少！和$？在非工作反引号命令之后？
非工作命令是否正在向 stderr 写入任何内容？

Answer 3

我怀疑问题出在这一行：

$instance_id = $1;

$1 是一个全局变量。人们永远不应该使用未经测试的 $1 等，因为它：

包含来自
对应的捕获集
上次成功的括号
模式匹配

（来自perldoc perlvar）

换句话说，如果没有匹配，则不会被覆盖。您可能会做这样的事情：

die $! unless ( $outp =~ /INSTANCE\s+(i-\w+)\s/ );
$instance_id = $1;

我尽量不使用未经测试的 $1 ，当然有很多方法可以确保它来自正确的地方。