核心文本性能

Question

当 Core Text 在原始 iPad 上运行时，我发现它存在一些性能问题。

我使用 Core Text 和基于 OmniGroup 的 OUIEditableFrame 的 UITextInput 协议创建了一个可编辑视图。

当视图中有大量文本（例如 180 行）时，键入/输入会大大滞后，并且按一下按键通常需要 1-2 秒。

使用带有模拟器的仪器，我能够缩小问题范围并找出是什么花了这么多时间。事实证明，这是因为我每次击键都会重新绘制框架，所以占用了这么多时间的是调用 CTFramesetterCreateWithAttributedString 和 CTFramesetterCreateFrame。

我必须在每次击键时重新绘制，以便更新文本，这意味着调用 CTFramesetterCreateWithAttributedString 和 CTFramesetterCreateFrame。

还有其他人遇到过这个问题吗？如果有，他们是如何解决的？

---

编辑：

做了一些进一步的调查，结果发现，如果属性字符串没有属性，那么所有内容都会绘制得更快并且没有任何延迟。更改字体、颜色或段落样式都会减慢速度。知道这是否与此有关吗？

Answer 1

您可能不应该使用 CTFramesetter 来创建类似 UITextView 的内容。相反，您可能应该保留一个 CTLine 引用数组。如果您需要断字方面的帮助，那么您可以使用 CTTypeSetter，但您只需将当前插入符号及以下的行交给它（您仍然会创建和销毁排字机，所以看看你对他们的要求有多少）。

保留 CTLines 数组的一个好处是，如果内存不足，您可以丢弃不需要的 CTLines 并在以后重建它们。只需跟踪每行的字符范围即可。

Answer 2

自从我最初的问题以来，我做了一些更多的调查，发现绘制的字符串具有的属性越多，花费的时间就越长。

有了这些知识，我决定简单地删除/隐藏用户看不到的任何属性（特别是kCTForegroundColor），这将绘图速度提高了十倍，并使其成为更可用的体验。

Answer 3

另一种方法是继续使用 CTFramesetter，但使用较小的 CTFrame。只需将您的 NSAttributedString 转换为子字符串（例如，使用 [NSString paragraphRangeForRange:] 获取段落范围，然后使用 attributeSubstringFromRange: 分解您的属性字符串）。然后为每个段落创建一个 CTFrame。当某些内容发生变化时（例如，用户键入某些内容），您只需更新发生变化的 CTFrame。

这意味着您可以继续利用 CTFramesetter 提供的功能，而不会因每次重新设置所有文本而造成性能损失。

Answer 4

我一直在尝试使用 CTLines 和 UITableView 在 iOS 上进行语法突出显示。 tableView 的伟大之处在于您可以刷新、删除和插入一行，并且只能重绘该行。

CTFramesetterCreateWithAttributedString 确实很慢。所以你用得越少越好。如果用户输入一些内容，您不需要再次将整个文本拆分成行，您可以只更新当前行，如果它溢出，您可以插入新行。要使其在每种情况下都能正常工作需要做一些工作，但性能可能会令人惊叹。

这就是我所做的：https://github.com/Anviking/Chromatism。

Answer 5

在没有框架设置器的情况下布局文本时，我需要像 Rob Napier 建议的类似功能。然而，罗布的答案看起来与用框架设置器布置时并不完全相同，所以我稍微修改了它：
https://gist.github.com/jpiringer/75ed6e666832d1f8201a6b2c79610736

#include "CustomLayouter.hpp"

#import <Foundation/Foundation.h>

#include <CoreText/CoreText.h>

#include <malloc/malloc.h>

static const CFRange kRangeZero = {0, 0};

CFIndex layoutTextInRectangle(CGContextRef context, CGRect rect, CFAttributedStringRef attributedString, CFIndex startLocation, float justificationWidth, float baselineGrid, float baselineGridOffsetY) {
    // Calculate the lines
    CFIndex start = startLocation;
    CGFloat boundsWidth = rect.size.width;
    CGPoint textPosition = CGPointMake(rect.origin.x, rect.origin.y+rect.size.height);
    CTTypesetterRef typesetter;
    CGPoint *positionsBuffer = nullptr;
    CGGlyph *glyphsBuffer = nullptr;

    typesetter = CTTypesetterCreateWithAttributedString(attributedString);
    NSUInteger length = CFAttributedStringGetLength(attributedString);
    while (start < length && textPosition.y > rect.origin.y) {
        CFIndex count = CTTypesetterSuggestLineBreak(typesetter, start, boundsWidth);
        CTLineRef line = CTTypesetterCreateLine(typesetter, CFRangeMake(start, count));
        
        CGFloat ascent;
        CGFloat descent;
        CGFloat leading;
        double lineWidth = CTLineGetTypographicBounds(line, &ascent, &descent, &leading);
        CGFloat lineHeight = ascent+descent+leading;
        
        if (textPosition.y-lineHeight <= rect.origin.y) {
            break;
        }

        if (justificationWidth > 0) {
            // Full-justify if the text isn't too short.
            if ((lineWidth / boundsWidth) > justificationWidth) {
                CTLineRef justifiedLine = CTLineCreateJustifiedLine(line, 1.0, boundsWidth);
                CFRelease(line);
                line = justifiedLine;
            }
        }

        CGContextSetTextPosition(context, textPosition.x, ceilf(textPosition.y-ascent));
        
        // Get the CTRun list
        CFArrayRef glyphRuns = CTLineGetGlyphRuns(line);
        CFIndex runCount = CFArrayGetCount(glyphRuns);
        
        for (CFIndex runIndex = 0; runIndex < runCount; ++runIndex) {
            CTRunRef run = (CTRunRef)CFArrayGetValueAtIndex(glyphRuns, runIndex);
            CTFontRef runFont = (CTFontRef)CFDictionaryGetValue(CTRunGetAttributes(run),
                                                     kCTFontAttributeName);
            
            //CGFloat lineHeight = getLineHeight(runFont);
            //NSLog(@"lineHeight: %f == %f", lineHeight, ascent+descent+leading);
            
            // FIXME: We could optimize this by caching fonts we know we use.
            CGFontRef cgFont = CTFontCopyGraphicsFont(runFont, nullptr);
            CGContextSetFont(context, cgFont);
            CGContextSetFontSize(context, CTFontGetSize(runFont));
            CFRelease(cgFont);
            
            CFIndex glyphCount = CTRunGetGlyphCount(run);
            
            // This is slightly dangerous. We're getting a pointer to the internal
            // data, and yes, we're modifying it. But it avoids copying the memory
            // in most cases, which can get expensive.
            CGPoint *positions = (CGPoint*)CTRunGetPositionsPtr(run);
            if (positions == nullptr) {
                size_t positionsBufferSize = sizeof(CGPoint) * glyphCount;
                if (malloc_size(positionsBuffer) < positionsBufferSize) {
                    positionsBuffer = (CGPoint *)realloc(positionsBuffer, positionsBufferSize);
                }
                CTRunGetPositions(run, kRangeZero, positionsBuffer);
                positions = positionsBuffer;
            }
            
            // This one is less dangerous since we don't modify it, and we keep the const
            // to remind ourselves that it's not to be modified lightly.
            const CGGlyph *glyphs = CTRunGetGlyphsPtr(run);
            if (glyphs == nullptr) {
                size_t glyphsBufferSize = sizeof(CGGlyph) * glyphCount;
                if (malloc_size(glyphsBuffer) < glyphsBufferSize) {
                    glyphsBuffer = (CGGlyph *)realloc(glyphsBuffer, glyphsBufferSize);
                }
                CTRunGetGlyphs(run, kRangeZero, (CGGlyph*)glyphs);
                glyphs = glyphsBuffer;
            }
            CGContextShowGlyphsAtPositions(context, glyphs, positions, glyphCount);
        }
        
        // Move the index beyond the line break.
        start += count;
        textPosition.y -= floorf(descent + leading + ascent);
        CFRelease(line);
    }
    free(positionsBuffer);
    free(glyphsBuffer);
    
    CFRelease(typesetter);
    
    if (start > length) {
        return 0;
    }
    return start;
}