检查子节点是否存在并应用模板

Question

我有以下简化的 XML 结构：

<?xml version="1.0" encoding="UTF-8"?>
<ExportData>
<TransportHeader>
    <Timestamp>2011-01-16 06:00:33</Timestamp>
    <From>
        <Name>DynamicExport</Name>
        <Version>1.</Version>
    </From>
    <MessageId>d7b5c5b69a83</MessageId>
</TransportHeader>
<ExportConfig>
    <DateTimeFormat>yyyy-MM-dd HH:mm:ss</DateTimeFormat>
    <DecimalSymbol>.</DecimalSymbol>
</ExportConfig>
<DataSet> 
    <Tables>
        <Table>
            <RH>...</RH>
            <Rows>
                <R>Data1</R>
                <R>Data2</R>
                <R>Data3</R>
                <R>Data4</R>
                <R>Data5</R>
            </Rows>
        </Table>
    </Tables>
</DataSet>
</ExportData>

我必须检查 元素是否存在。如果不存在 元素，则必须中止映射，否则每个 需要一个 元素被创建。

我想出了这个到目前为止效果很好的解决方案：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
<xsl:output encoding="ISO-8859-1" method="xml" indent="yes" />

<!-- suppress nodes that are not matched -->
<xsl:template match="text() | @*">
    <xsl:apply-templates select="text() | @*"/>
</xsl:template>

<xsl:template match="/">
    <xsl:choose>
        <xsl:when test="not(ExportData/DataSet/Tables/Table/Rows/node())">
            <xsl:message terminate="yes">No line items</xsl:message>
        </xsl:when>
        <xsl:otherwise>
            <xsl:apply-templates/>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

<xsl:template match="/ExportData/DataSet/Tables/Table/Rows">
    <INVOIC02>
        <!-- apply LINE ITEMS template -->
        <xsl:apply-templates select="R"/>
    </INVOIC02>
</xsl:template>

<!-- Template creating LINE ITEMS -->
<xsl:template match="R">
    
    <Line>
        <elements></elements>
    </Line>
</xsl:template>


</xsl:stylesheet>

如果有 元素，则输出是这样的：

<?xml version="1.0" encoding="ISO-8859-1"?>
<INVOIC02>
<Line>
    <elements/>
</Line>
<Line>
    <elements/>
</Line>
<Line>
    <elements/>
</Line>
<Line>
    <elements/>
</Line>
<Line>
    <elements/>
</Line>
</INVOIC02>

如果只有 并且没有映射被中止。

现在我有两个问题：

- 我对 元素的测试是否可靠：test="not(ExportData/DataSet/Tables/Table/Rows/node())"？

-我使用 创建 项，而不是 代码>构造。我的 XPath 表达式还可以吗？或者我可以改进它们吗？

Answer 1

我对元素的测试是否稳健： test="not(ExportData/DataSet/Tables/Table/Rows/node())"
？

好吧，您是否希望它在没有 R 元素时失败，或者在 Rows 没有子 node() 时失败，这将包括任何元素（不仅仅是R）、text()、comment()或processing - 指令（）？

如果您确实想验证是否至少有一个 R 元素是 Rows 的子元素，您应该将测试标准调整得更具体：< /strong>

test="not(ExportData/DataSet/Tables/Table/Rows/R)"

否则，它可能会通过该测试并继续处理，但不会生成您想要的内容。

我正在使用 ;创建<线>项目而不是 
构造。 
我的 XPath 表达式还可以吗？或者我可以改进它们吗？

您可以删除根节点模板内的 条件逻辑，并将该逻辑移至不包含的 Rows 模板中R 孩子。将逻辑放入 xsl:template @match 标准中可以使 XSLT 处理器更容易优化，从而提高性能。

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:output encoding="ISO-8859-1" method="xml" indent="yes" />

    <!-- suppress nodes that are not matched -->
    <xsl:template match="text() | @*">
        <xsl:apply-templates select="text() | @*"/>
    </xsl:template>

    <!--All Rows must contain an R.  
        If we encounter any that do not, terminate the transform -->
    <xsl:template match="/ExportData/DataSet/Tables/Table/Rows[not(R)]">
        <xsl:message terminate="yes">No line items</xsl:message>
    </xsl:template>

    <!--match for Rows that have R children -->
    <xsl:template match="/ExportData/DataSet/Tables/Table/Rows[R]">
        <INVOIC02>
            <!-- apply LINE ITEMS template -->
            <xsl:apply-templates select="R"/>
        </INVOIC02>
    </xsl:template>

    <!-- Template creating LINE ITEMS -->
    <xsl:template match="R">      
        <Line>
            <elements></elements>
        </Line>
    </xsl:template>

</xsl:stylesheet>

Answer 2

这将检查 R 节点是否有子元素：

<xsl:if test="R">
   <!--What you want to do here-->
</xsl:if>