如何从嵌套 Oracle 过程中检索值？

Question

我遇到了一个棘手的 Oracle 问题。我正在尝试选择一组数据，我们将其称为项目。对于每个项目，我想调用另一个过程并返回一个库存项目。我有两项手术，我不确定如何执行。

1. 如何从嵌套过程中检索值？

2. 如何以 SYS_REFCURSOR 的形式返回这些检索到的值？

我在这里的尝试是将 spSelect_Inv_Search 的结果放入名为 ITEMS_TABLE 的嵌套表中。这是行不通的。

下面的代码

PROCEDURE SPSELECT_ITEM (IO_CURSOR OUT SYS_REFCURSOR) 
AS   
  MY_CURSOR SYS_REFCURSOR;
  TYPE ITEM_TYPE IS TABLE OF ITEMS.ITEM_NO%TYPE;
  ITEM_TABLE ITEM_TYPE := ITEM_TYPE();

  CURSOR ITEMS_CURSOR IS
      SELECT ITEM_NO 
      FROM ITEMS;

  V_COUNTER INTEGER := 0;
BEGIN
  FOR ITEM_REC IN ITEM_CURSOR LOOP
    V_COUNTER := V_COUNTER + 1;
    ITEM_TABLE.EXTEND;
    ITEM_TABLE(V_COUNTER) := spSelect_Inv_Search(ITEM_REC.ITEM_NO, MY_CURSOR);
  END LOOP;
END SPSELECT_ITEMS;

非常感谢任何帮助，谢谢。

Answer 1

您似乎想要将未知数量的 SYS_REFCURSOR 结果集合并为一个大结果集。如果您知道从 spSelect_Inv_Search 返回的游标的结构，您可以使用中间管道函数来完成此操作。

create package p as
    type tmp_rec_type is record (owner all_objects.owner%type,
        object_type all_objects.object_type%type,
        objects number);
    type tmp_rec_table is table of tmp_rec_type;

    procedure proc1(p_owner in varchar2, p_cursor out sys_refcursor);
    function func2 return tmp_rec_table pipelined;
    procedure proc3(p_cursor out sys_refcursor);
end;
/

类型可以在此处定义，它们不必在 SQL 级别，因为您不需要在包外部引用它们。

create package body p as
    procedure proc1(p_owner in varchar2, p_cursor out sys_refcursor) as
    begin
        open p_cursor for select owner, object_type, count(*)
            from all_objects
            where owner = p_owner
            group by owner, object_type;
    end;

    function func2 return tmp_rec_table pipelined as
        cursor c1 is select distinct owner
            from all_tables where owner in ('SYS','SYSTEM');
        tmp_cursor sys_refcursor;
        tmp_rec tmp_rec_type;
    begin
        for r1 in c1 loop
            proc1(r1.owner, tmp_cursor);
            loop
                fetch tmp_cursor into tmp_rec;
                exit when tmp_cursor%notfound;
                pipe row(tmp_rec);
            end loop;
        end loop;
    end;

    procedure proc3(p_cursor out sys_refcursor) as
    begin
        open p_cursor for select * from table(func2);
    end;
end p;
/

然后执行，尽管中间阶段使用了类型，但您可以在包外部执行此操作，您可以在 SQL*Plus 或 SQL Developer 中执行此操作以进行测试：

var rc refcursor;
exec p.proc3(:rc);
print rc;

对于我的数据库，这给出：

OWNER                          OBJECT_TYPE         OBJECTS                
------------------------------ ------------------- ---------------------- 
SYSTEM                         VIEW                1                      
SYSTEM                         TABLE               5                      
SYS                            VIEW                1056                   
SYS                            CONSUMER GROUP      2                      
SYS                            PROCEDURE           11                     
SYS                            FUNCTION            56                     
SYS                            SEQUENCE            1                      
SYS                            OPERATOR            6                      
SYS                            EVALUATION CONTEXT  1                      
SYS                            TABLE               13                     
SYS                            WINDOW GROUP        1                      
SYS                            PACKAGE             162                    
SYS                            WINDOW              2                      
SYS                            TYPE                529                    
SYS                            JOB CLASS           1                      
SYS                            SCHEDULE            1     

这显然是非常人为的，就像您所做的那样这是一个单一的查询，但我假设您的内部过程需要做一些更复杂的事情。

Answer 2

为了回答有关如何调用 spSelect_Inv_Search 的问题，我需要知道该子程序的签名。您已将其描述为过程，但试图将其作为函数调用。是哪一个？它有什么返回值和/或 OUT 模式参数？

要从上述过程返回打开的 REF CURSOR，首先需要在架构级别（使用 CREATE TYPE 语句）而不是在 PL/SQL 代码中声明嵌套表类型。然后，在填充嵌套表后，您可以像这样打开游标。

OPEN io_cursor FOR SELECT * FROM TABLE(CAST(item_table AS item_type));

（顺便说一下，我自己将类型的名称从 ITEM_TYPE 更改为 ITEM_TABLE_TYPE。）