获取任何元素的变化

Question

我有一个带有一些组件（textInput、textArea、checkBox）的屏幕。我想检查一下组件是否有任何变化。例如，如果已输入文本或已单击复选框。

有没有直接的方法来做到这一点，而不是检查每个组件的值，然后为此设置一个布尔值？

谢谢

Answer 1

您列出的三个 Spark 组件（TextInput、TextArea、CheckBox）都侦听更改事件。只需调用一个函数即可在每个组件上发生更改事件时收到通知，如下所示：

<s/TextInput change="myTextInputChangeHandler(event)"/>
<s/TextArea change="myTextAreaChangeHandler(event)"/>
<s/CheckBox change="myCheckBoxChangeHandler(event)"/>

Answer 2

您可以创建一些包含数据并跟踪更改的类。并使用两种方式绑定将控件与该数据对象字段绑定。

数据对象的基类如下所示：

public class DataObjectsBase extends EventDispatcher
{
    protected function setNewSetterValue(propertyName:String, value:Object):void
    {
        var internalPropertyName:String = "_" + propertyName;
        var oldValue:Object = this[internalPropertyName];
        if (oldValue == value)
            return;
        this[internalPropertyName] = value;
        dispatchUpdateEvent(propertyName, oldValue, value);
    }

    protected function dispatchUpdateEvent(propertyName:String, oldValue:Object, value:Object):void
    {
        makeChanges();
        dispatchEvent(PropertyChangeEvent.createUpdateEvent(this, propertyName, oldValue, value));
    }

    protected function makeChanges():void
    {
        if (!_changed)
        {
            _changed = true;
            dispatchEvent(new Event("changedChanged"));
        }
    }

    public function resetChanges():void
    {
        _changed = false;
        dispatchEvent(new Event("changedChanged"));
    }

    private var _changed:Boolean = false;

    [Bindable("changedChanged")]
    public function get changed():Boolean
    {
        return _changed;
    }
}

此实现依赖于以下类型的命名约定：

public class MyDataImplementation extends DataObjectsBase
{
    private var _comment:String = "";

    [Bindable(event = "propertyChange")]
    public function get comment():String
    {
        return _comment;
    }

    public function set comment(value:String):void
    {
        setNewSetterValue("comment", value);
    }
}

因此私有字段的命名应与访问器相同，但以下划线开头。

如果您用多个字段（字符串、布尔值等）填充数据类，您可以按以下方式使用它：

<fx:Script>
<![CDATA[
    [Bindable]
    private var personalInfo:PersonalInfo /* extends our DataObjectsBase */;
]]>
</fx:Script>
<s:TextInput text="@{personalInfo.firstName}" />
<s:CheckBox selected="@{personalInfo.receivePromotions}" />
<s:Button label="Apply" enabled="{personalInfo.changed}" />

此代码只是一个草稿，但我希望您明白:)

Answer 3

您可以在每个组件上注册一个事件侦听器以自动侦听更改。

如果您试图弄清楚从特定时间（或最后检查的实例）是否发生了更改，唯一的方法（我知道）是存储先前的输入（输入的哈希值）并将其与当前输入（输入的哈希值）进行比较当前输入）。