F# 中的广度优先搜索 (BFS)

Question

我想使用 BFS 实现搜索。该算法说我必须使用队列才能获得 FIFO 效果。 我读了 Chris Okasaki 的纯函数式数据结构一书，并找到了如何创建队列（我使用 F# 编写）：

type 'a queue = 'a list * 'a list
let emtpy = [],[]
let isEmpty = function
    | [],_ -> true
    | _ -> false

let checkf = function
    | [],r -> List.rev r,[]
    | q -> q

let snoc (f,r) x = checkf (f,x :: r)

let head = function
    | ([],_) -> failwith "EMPTY"
    | (x::f,r) -> x

let tail = function
    | ([],_) -> failwith "EMPTY"
    | (x::f,r) -> checkf (f,r)

有人知道如何将其实现到 BFS 吗？

我有这个代码可以从列表中创建一棵树：（

let data = [4;3;8;7;10;1;9;6;5;0;2]

type Tree<'a> = 
    | Node of Tree<'a> * 'a * Tree<'a>
    | Leaf

let rec insert tree element = 
    match element,tree with
    | x,Leaf        -> Node(Leaf,x,Leaf)
    | x,Node(l,y,r) when x <= y -> Node((insert l x),y,r)
    | x,Node(l,y,r) when x > y -> Node(l,y,(insert r x))
    | _ -> Leaf

let makeTree = List.fold insert Leaf data

想要结合这两个代码）

Answer 1

BFS 算法是这样的：

Initialise the search by placing the starting vertex in the queue.
While the queue is not empty.
  Remove the front vertex from the queue.
  If this is a solution then we're finished -- report success.
  Otherwise, compute the immediate children of this vertex and enqueue them.
Otherwise we have exhausted the queue and found no solution -- report failure.

我的 F# 语法有点不稳定，但我将如何勾勒出解决方案：

bfs start = bfsLoop ([start], [])

bfsLoop q0 =
  if   isEmpty q0
  then failWith "No solution"
  else v = head q0
       if   isSolution v
       then v
       else q1 = tail q0
            vs = childrenOf v
            q = foldl snoc vs q1
            bfsLoop q

希望这会有所帮助。

Answer 2

11年后可能还有用吗？

F# 中的 BFS 并不难：您可以使用递归来代替 while 循环来保持其不可变。

我将每个节点及其踪迹排入队列，以便我们可以计算解决方案路径。

let data = [4;3;8;7;10;1;9;6;5;0;2]

type Tree<'a> = 
    | Node of Tree<'a> * 'a * Tree<'a>
    | Leaf

let rec insert tree element = 
    match element,tree with
    | x,Leaf        -> Node(Leaf,x,Leaf)
    | x,Node(l,y,r) when x <= y -> Node((insert l x),y,r)
    | x,Node(l,y,r) when x > y -> Node(l,y,(insert r x))
    | _ -> Leaf

let tree = List.fold insert Leaf data

// BFS
let rec find goal queue =
  match queue with
  | []                          -> None
  | (Leaf, _)::tail             -> find goal tail
  | (Node (l,y,r), trace)::tail ->
    if y = goal then Some (List.rev (y::trace)) else
    find goal (tail @ [ l, y::trace; r, y::trace ])

// for example, to find the 5 in your tree
find 5 [tree, []]
|> printfn "%A"

// it will return: Some [4; 8; 7; 6; 5]
// because your tree looks like this:
//         4
//      /     \
//     3       8
//    /       / \
//   1       7   10
//  / \     /   /
// 0   2   6   9
//        /
//       5