Perl 数组与列表

Question

我在 Perl 中有两个数据结构：

一个数组：

my @array2 = ( "1", "2", "3");

for $elem (@array2) {
    print $elem."\n";
}

给出以下输出：

1
2
3

和一个列表：

my @array = [ "1", "2", "3"];                                            

for $elem (@array) {
    print $elem."\n";
}

给出以下输出：

ARRAY(0x9c90818)

显然，我想在这两种情况下迭代元素，但为什么第二个解决方案只给我对此数组的引用？

Answer 1

在 Perl 中，数组和列表本质上是相同的东西，但您的第二个示例两者都不使用。方括号括住数组引用（标量值），并且使用诸如 my @array = $scalar 之类的内容将标量“分配”给数组相当于 我的@array = ($scalar)。因此，第二个示例中 @array 的唯一元素是数组引用。

Answer 2

Perl 中的列表不是数据结构，它们是源代码中的位置，由它们周围的上下文决定。列表基本上是 Perl 用于移动数据的瞬态结构。您可以使用 Perl 的所有语法与它们交互，但不能将它们作为数据类型使用。最接近列表的数据类型是数组。

my @var    =    (1, 2, 3);  # parens needed for precedence, they do not create a list
   ^ an array    ^ a list

say 1, 2, 3;
    ^ a list

say @var;
    ^ a list (of one array, which will expand into 3 values before `say` is called)

当您编写 [1, 2, 3] 时，您所做的是创建一个标量数组引用。该数组引用使用列表 1, 2, 3 进行初始化，它与创建命名数组并引用它相同：

[1, 2, 3]   ~~   do {my @x = (1, 2, 3); \@x}

由于 [...] 构造创建一个标量，您应该将其保存在标量中：

my $array = [1, 2, 3];                                            

for my $elem (@$array) {   # lexical loop variable
    print $elem."\n";
}

由于您想要操作整个数组，而不仅仅是引用，因此您可以在 $ 前面放置一个 @ array 取消引用存储的数组引用。

Answer 3

方括号用于创建匿名数组。计算时，它返回对此数组的引用，而不是实际的数组值。

括号没有这样的隐藏属性，而是简单地覆盖表达式内部的优先级，就像数学中一样。例如：

my @array = 1,2,3;

实际上是这样计算的：

my @array = 1;
2,3; # causes the warning "Useless use of constant in void context"

因为 = 运算符的优先级高于逗号。因此，为了解决这个问题，我们在分配数组时使用括号，如下所示：

my @array = (1,2,3);

您的示例：

my @array = [1,2,3];

有点像这样说：

my @tmp = (1,2,3);
my @array = \@tmp;

其中 \ 用于创建对 @tmp数组。

Answer 4

方括号创建一个匿名数组，用方括号的内容填充该数组，并返回对该数组的引用。换句话说，

[ "1", "2", "3" ]

与 基本相同

do { my @anon = ("1", "2", "3"); \@anon }

所以代码应该类似于

my $array_ref = [ "1", "2", "3" ];

for (@$array_ref) {  # Short for @{ $array_ref }
    print "$_\n";
}

或

my @array_of_refs = ([ "1", "2", "3" ]);

for my $array_ref (@array_of_refs) {
    for (@$array_ref) {
        print "$_\n";
    }
}

Answer 5

如果您需要更多说明，请参阅相关文档。

为了说明目的，您可以尝试做一些事情：

#!perl -lw # -l appends a \n to each print, -w enables warnings
use strict;
my $aryref = [1 .. 5];
print for $aryref;    # Prints the stringified reference - not what you want
print for @$aryref;   # Dereferencing it lets you access the array
my @ary = $aryref;    # Probably not what you want
print for @ary;       # Stringified reference again
print for @{$ary[0]}; # Dereference the first array element (which holds the ref)

Answer 6

@array = ("1","2","3");
这里1,2,3是@array变量的元素。对于前。 $array[0] 为 1 ，$array[1] 为 2 ，$array[2] 为 3。

@array = ["1","2","3"];
Perl 使用 [ ] 来使用匿名数组引用，因此这里基本上只存储一个元素，即数组 ["1","2","3"] 对 @array 变量的引用。例如 $array[0] 是“ARRAY(0x9c90818)”
因此，在打印时它会向您显示参考文献。