Perl映射块局部变量的使用

Question

此代码通过一组路径中唯一基本名称存根的哈希键来编译一组。

%stubs = map { $f=basename $_; $f =~ /^([A-Za-z]+[0-9]+)\./ ; $1=>() } @pathlist;

为什么这里需要 $f 引用？我以为我可以接受：

%stubs = map { basename; /^([A-Za-z]+[0-9]+)\./; $1=>() } @pathlist;

但我没有匹配到。我是否不允许修改地图块中的 $_ ？

对于那些想知道代码在做什么的人：

对于每个 $path (@pathlist)，它获取基本名称，匹配第一个字母数字序列，然后返回第一个括号匹配作为空列表值上的键。示例：

/some/dir/foo123.adfjijoijb
/some/dir/foo123.oibhobihe
/some/dir/bar789.popjpoj

返回

foo123 => ()
bar789 => ()

之后，我使用映射的键作为值集进行处理。

Answer 1

basename 并不默认作用于 $_。但是您可以匹配它的返回值，而不是使用 $f：

%stubs = map { basename($_) =~ /^([A-Za-z]+[0-9]+)\./; $1 => undef } @pathlist;

请注意，列表中的 () 不会生成元素，它只是扁平化为空；你必须提供一个值，即使只是undef。与 $1 => ()，映射迭代将交替为 %stubs 生成一个键和一个值。

在使用 $1 之前总是检查你的正则表达式是否成功是很好的：

%stubs = map { basename($_) =~ /^([A-Za-z]+[0-9]+)\./ ? ($1 => undef) : () } @pathlist;

尽管如果你不介意哈希值是空字符串而不是 undef，你可以让正则表达式匹配返回所需的列表：

%stubs = map { basename($_) =~ /^([A-Za-z]+[0-9]+)()\./ } @pathlist;

Answer 2

在map和grep中，$_是数组中值的别名。如果修改它们，实际上就是修改数组中的值。这可能不是您想要的，也可能不是出了问题，但是在这两种情况下都要调试打印键 %stubs 和 @pathlist 并让我们知道它说的是什么。

另外：File::Basename 的基本名称不能隐式地作用于 $_。它为我生成一个错误。

#!/usr/bin/perl
use feature say;
use File::Basename;

@pathlist=("/some/dir/foo123.adfjijoijb","/some/dir/foo123.oibhobihe","/some/dir/bar789.popjpoj");
%stubs1 = map { $f=basename $_; $f =~ /^([A-Za-z]+[0-9]+)\./ ; $1=>() } @pathlist;
say join(',',keys %stubs1);
say "---";
say join(',',@pathlist);
say "---";

%stubs = map { $_=basename $_; /^([A-Za-z]+[0-9]+)\./; $1=>() } @pathlist;
say join(',',keys %stubs);
say "---";
say join(',',@pathlist);
say "---";

%stubs = map {basename; /^([A-Za-z]+[0-9]+)\./; $1=>() } @pathlist;

Answer 3

替代实施：

my %stubs =
   map { $_ => undef }
   map { basename($_) =~ /^([A-Za-z]+[0-9]+)\./ }
   @pathlist;