Prolog列表问题

Question

[a,b,c,d] and
[[1,2,3,4],[5,6,7,8],[43,34,56,5],[23,32,2,2]]

我想让

[[a,1,2,3,4],[b,5,6,7,8],[c,43,34,56,5],[d,23,32,2,2]]

我使用 swi prolog 可以吗？

多谢。

Answer 1

SWI Prolog 可以使用两个短谓词来完成此操作：

merge0(A, B, Prev, Next) :- append(Prev, [[A|B]], Next).
merge(A, B, Result) :- foldl(merge0, A, B, [], Result).

以下是输入和输出的示例：

a(X) :- X = [a,b,c,d].
b(X) :- X = [[1,2,3,4],[5,6,7,8],[43,34,56,5],[23,32,2,2]].

?- a(A), b(B), merge(A, B, Result).

Result = [[a, 1, 2, 3, 4], [b, 5, 6, 7, 8], [c, 43, 34, 56, 5], [d, 23, 32, 2, 2]].

Answer 2

试试这个：

delete(X, [X|T], T).

delete(X, [Y|T], [Y|L]):-
delete(X, T, L).

insert(X, List, BigList):-
  delete(X, BigList, List).

if([],X,X).

if([H1|T1],[H2|T2],[SH|ST]):-
  insert(H1,H2,SH),!,
  if(T1,T2,ST).

我仔细检查过，它有效。

“if”代表“先插入”。

Answer 3

solve([], [], []).

solve([[X|Y]|S], [X|L1], [Y|L2]):-
  solve(S, L1, L2).

更新： 如何使用

将函数写在文件“a.pl”中，然后在 swi-prolog 中输入：

['a.pl'].

然后输入：

solve(X, [a,b,c,d], [[1,2,3,4],[5,6,7,8],[43,34,56,5],[23,32,2,2]]).

你会得到：

X = [[a, 1, 2, 3, 4], [b, 5, 6, 7, 8], [c, 43, 34, 56, 5], [d, 23, 32, 2, 2]] 

我有一种奇怪的感觉，我正在做你的作业。是吗？

Answer 4

使用 meta-predicate maplist/4 和 Prolog lambda 像这样：

?- As  = [a,b,c,d], 
   Bss = [[1,2,3,4],[5,6,7,8],[43,34,56,5],[23,32,2,2]],
   maplist(\H^T^[H|T]^true,As,Bss,Css).
As  = [ a         , b         , c            , d           ],
Bss = [[  1,2,3,4],[  5,6,7,8],[  43,34,56,5],[  23,32,2,2]],
Css = [[a,1,2,3,4],[b,5,6,7,8],[c,43,34,56,5],[d,23,32,2,2]].

---

编辑

可以使用不同的 lambda 术语正如评论中指出的，在上面的 maplist/4 目标中。

• maplist(\H^T^[H|T]^true,As,Bss,Css)
• maplist(\H^T^ =( [H|T]) ,As,Bss,Css)