vb 2008 WriteProcessMemory() 返回 0

Question

你好 我正在使用 vb 2008 这是我的代码的一部分：

Private Declare Function WriteProcessMemory Lib "kernel32" Alias "WriteProcessMemory" ( _
      ByVal hProcess As Integer, _
      ByVal lpBaseAddress As Integer, _
      ByVal lpBuffer As Integer, _
      ByVal nSize As Integer, _
      ByVal lpNumberOfBytesWritten As Integer _
   ) As Integer

    Dim proc() As Process = Process.GetProcessesByName("process")
    If proc.Length = 0 Then Console.WriteLine("Process Not Found") : Exit Sub
    Dim p = proc(0)
    Dim pH As Integer = OpenProcess(PROCESS_ALL_ACCESS, 0, p.Id)
    Dim address As Integer
    address = &H98544
    Dim memory As IntPtr
    Call ReadProcessMemory(pH, address, memory, 4, 0)
    Console.WriteLine(memory.ToString)
    Dim data As Integer = 2000
    Call WriteProcessMemory(pH, address, data, Len(data), 0&)

但是，WriteProcessMemory() 返回 0，并且值不会改变

解决方案：

<DllImport("kernel32", CharSet:=CharSet.Auto, SetLastError:=True)> _
Private Shared Function WriteProcessMemory( _
                                      ByVal hProcess As IntPtr, _
                                      ByVal lpBaseAddress As IntPtr, _
                                      ByVal lpBuffer As Byte(), _
                                      ByVal nSize As UInt32, _
                                      ByRef lpNumberOfBytesWritten As UInt32 _
                                      ) As Boolean
End Function

        Dim proc() As Process = Process.GetProcessesByName("process")
        If proc.Length = 0 Then Console.WriteLine("Process Not Found") : Exit Sub
        Dim p = proc(0)
        Dim pH As Integer = OpenProcess(PROCESS_ALL_ACCESS, 0, p.Id)
        Dim address As Integer
        address = &H98544
        Dim memory As IntPtr
        Call ReadProcessMemory(pH, address, memory, 4, 0)
        Console.WriteLine(memory.ToString)
        Dim data() As Byte = BitConverter.GetBytes(2000)
        Call WriteProcessMemory(pH, address, data, 4, 0&)

Answer 1

当你调用Windows API函数时，你必须自己实现错误检查代码。当出现问题时，它们不会像标准 .NET Framework 函数那样抛出异常。

所需的具体错误检查因功能而异。 （像这样的不一致正是 .NET 使用异常的原因。）检查文档至关重要。

WriteProcessMemory 的工作方式是相当常见。返回值为 BOOL（Win32 库将其视为布尔值的整数，其中 0 = FALSE，1 = TRUE）。如果函数失败，返回值为 0 (FALSE)。如果成功，返回值为 1 (TRUE)：

如果函数成功，返回值非零。

如果函数失败，返回值为 0（零）。要获取扩展错误信息，请调用GetLastError。如果请求的写入操作跨越了进程中不可访问的区域，则该函数将失败。

当然，有趣的部分是我们被告知必须调用 GetLastError 函数才能确定函数失败的原因。其中一部分是正确的。 您仅调用GetLastError 当您编写非托管 C++ 代码时。在.NET 中，您需要做其他事情。有两个步骤：

1. 使用 SetLastError = True 标记 P/Invoke 签名，这会导致 CLR 自动调用 GetLastError 并保存其值。
2. 调用 Marshal.GetLastWin32Error 检索该值。

因此，要调试它，您需要像这样重新编写代码（使用标准 P/Invoke 语法，而不是 VB.NET 特有的更有限的 Declare 关键字）：

<DllImport("kernel32", CharSet:=CharSet.Auto, SetLastError:=True)>
Private Shared Function WriteProcessMemory(
                                           ByVal hProcess As Integer, _
                                           ByVal lpBaseAddress As Integer, _
                                           ByVal lpBuffer As Integer, _
                                           ByVal nSize As Integer, _
                                           ByVal lpNumberOfBytesWritten As Integer _
                                          ) As Integer
End Function

Dim proc() As Process = Process.GetProcessesByName("process")
If proc.Length = 0 Then Console.WriteLine("Process Not Found") : Exit Sub
Dim p = proc(0)
Dim pH As Integer = OpenProcess(PROCESS_ALL_ACCESS, 0, p.Id)
Dim address As Integer
address = &H98544
Dim memory As IntPtr
Call ReadProcessMemory(pH, address, memory, 4, 0)
Console.WriteLine(memory.ToString)
Dim data As Integer = 2000
If WriteProcessMemory(pH, address, data, Len(data), 0&) = 0 Then
   ' The function failed, so find out what the error was
   MessageBox.Show("WriteProcessMemory failed with error " & Marshal.GetLastWin32Error)
End If

知道错误代码后，您可以在系统错误列表中查找它代码看看它的意思。

---

结果错误是编号 299，ERROR_PARTIAL_COPY，文档说的意思是：

仅完成了 ReadProcessMemory 或 WriteProcessMemory 请求的一部分。

嗯，不是很有帮助...我希望你能得到更好的东西。 这就是生活。

您将必须具备一些额外的知识才能解决该问题。文档中再次给出了提示。任何时候它说参数是“指针”（在C++语法中用星号*表示），这意味着在VB.NET中，需要传递它作为参考，而不是作为值。要指定将某些内容作为引用传递，请使用 ByRef 关键字。当然，要按值传递，您需要指定默认的 ByVal 关键字。

另外，请注意，当文档说某物是句柄或地址时，您应该在VB.NET中将其声明为IntPtr 类型，而不是整数。 IntPtr 很特殊，因为它的大小会发生变化，具体取决于底层操作系统是 32 位还是 64 位（与整数不同，整数是固定大小的，无论您在什么平台上运行） ）。尽管这不会立即导致问题，但在编译 64 位代码时会导致兼容性问题。

所以事实证明你的声明实际上是错误的。像这样重新声明：

<DllImport("kernel32", CharSet:=CharSet.Auto, SetLastError:=True)>
Private Shared Function WriteProcessMemory(
                                           ByVal hProcess As IntPtr, _
                                           ByVal lpBaseAddress As IntPtr, _
                                           ByVal lpBuffer As Integer, _
                                           ByVal nSize As Integer, _
                                           ByRef lpNumberOfBytesWritten As Integer _
                                          ) As Integer
End Function

您可能还认为第三个参数（lpBuffer）应该是一个字节数组（Byte()），因为它指定要写入的数据到地址空间。

Answer 2

文档指出：

如果函数失败，则返回
值为 0（零）。为了得到延长
错误信息，调用GetLastError。
如果请求，该功能将失败
写操作跨入一个区域
无法访问的进程。

我建议您按照它的说明进行操作，找出失败的原因。

指出这一点后，失败的原因似乎是您尝试写入的地址 2000 在该过程中不是有效地址。

lpBuffer 参数是一个指针，您将整数值 2000 作为该参数传递。因此，这被解释为内存地址。我怀疑您实际上打算传递data的地址。