使用 xslt 在分类布局中转换 xml

Question

我有一个像这样的 xml 文件：

<?xml version="1.0"?>
<BOOKS>
<BOOK category="Book">
    <TITLE image="./images/govnahDesign.jpg">Bible</TITLE>
    <PRICE>0.00</PRICE>
</BOOK> 
<BOOK category="Magazine">
    <TITLE image="./images/govnahDesign.jpg">Auto Mall</TITLE>
    <PRICE>10.00</PRICE>
</BOOK> 
<BOOK category="Magazine">
    <TITLE image="./images/govnahDesign.jpg">LyfeStyle</TITLE>
    <PRICE>40.00</PRICE>
</BOOK>
    </BOOKS>

我试图让它像这样显示：

Category: Book
   Bible
   <img>
   0.00
---------------------

Category: Magazine
   Auto Mall
   <img>
   10.00

   LyfeStyle
   <img>
   40.00

到目前为止，我的 XSL 输出如下：

Category: Book
   Bible
   <img>
   0.00
---------------------

Category: Magazine
   Auto Mall
   <img>
   10.00
---------------------

Category: Magazine
   LyfeStyle
   <img>
   40.00
---------------------

这是我的 XSL 文件：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">

<xsl:template match="/">
<xsl:for-each select="BOOKS/BOOK">

Category: <xsl:value-of select="@category"/>

<xsl:for-each select="@category">

<div class="item"><!--div has a float:left-->
    <xsl:value-of select="../TITLE"/>
    <img>
        <xsl:attribute name="src">
            <xsl:value-of select="../TITLE//@image"/>
        </xsl:attribute>
    </img>
    Price: <xsl:value-of select="../PRICE"/><br />
    <button id="view" onclick="javascript:viewProduct()">View</button>
</div>
<hr class="clear"/>
</xsl:for-each>

</xsl:for-each>
</xsl:template>
</xsl:stylesheet>

任何人都可以指出我正确的方向。谢谢

Answer 1

分组通常通过 Meunchan 方法来实现。在SO中你会找到很多关于的答案。这里你有一个可能的解决方案，只需对你的 xsl 做一点小小的改变：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">

 <xsl:key name="bybookcategory" match="BOOKS/BOOK" use="@category"/>

 <xsl:template  match="BOOKS">
  <xsl:for-each select="BOOK[generate-id()=generate-id(key('bybookcategory', @category)[1])]">
   Category: <xsl:value-of select="@category"/>
    <xsl:for-each select="key('bybookcategory', @category)">

     <div class="item"><!--div has a float:left-->
      <xsl:value-of select="TITLE"/>
      <img>
        <xsl:attribute name="src">
            <xsl:value-of select="TITLE//@image"/>
        </xsl:attribute>
      </img>
     Price: <xsl:value-of select="PRICE"/><br />
     <button id="view" onclick="javascript:viewProduct()">View</button>
     </div>
    <hr class="clear"/>
   </xsl:for-each>
  </xsl:for-each>
 </xsl:template>
</xsl:stylesheet>

Answer 2

Govnah，

在不更改 XML 的情况下，您可以采用如下路线：

http://www. jenitennison.com/xslt/grouping/muenchian.html

循环浏览您的书籍，但仅浏览那些没有“以下兄弟”且具有相同类别的书籍（即该类别的第一本）。然后在该循​​环中，循环遍历与当前类别匹配的书籍。

你能像这样修改你的XML吗？完成您所要求的操作并非不可能，但有时我发现调整 XML 是一种更简洁的方法。

<?xml version="1.0"?>
<BOOKS>
<CATEGORIES>
  <CATEGORY>Book</CATEGORY>
  <CATEGORY>Magazine</CATEGORY>
</CATEGORIES>
<BOOK category="Book">
    <TITLE image="./images/govnahDesign.jpg">Bible</TITLE>
    <PRICE>0.00</PRICE>
</BOOK> 
<BOOK category="Magazine">
    <TITLE image="./images/govnahDesign.jpg">Auto Mall</TITLE>
    <PRICE>10.00</PRICE>
</BOOK> 
<BOOK category="Magazine">
    <TITLE image="./images/govnahDesign.jpg">LyfeStyle</TITLE>
    <PRICE>40.00</PRICE>
</BOOK> 
</BOOKS>