为什么我会收到此错误？

Question

这是我的代码

#!/usr/bin/perl -T

use CGI;
use CGI::Carp qw(fatalsToBrowser);
use CGI qw(:standard);
use JSON;
use utf8;
use strict;
use warnings;


# ... ;

my $cgi = CGI->new;
$cgi->charset('UTF-8');

my @owners = map { s/\s*//g; $_ } split ",", $cgi->param('owner');
my @users  = map { s/\s*//g; $_ } split ",", $cgi->param('users');


my $json = JSON->new;
$json = $json->utf8;


my %user_result = ();
foreach my $u (@users) {
    $user_result{$u} = $db1->{$u}{displayName};
}

my %owner_result = ();
foreach my $o (@owners) {
    $owner_result{$o} = $db2{$o};
}

$json->{"users"}   = $json->encode(\%user_result);
$json->{"owners"}  = $json->encode(\%owner_result);

$json_string = to_json($json);

print $cgi->header(-type => "application/json", -charset => "utf-8");
print $json_string;

，这些行

$json->{"users"}   = $json->encode(\%user_result);
$json->{"owners"}  = $json->encode(\%owner_result);

给出了错误

Not a HASH reference

为什么我会得到这个错误？

如何解决这个问题？

Answer 1

JSON 对象（至少在 XS 版本中，见下文）只是一个 SCALAR 引用，因此您无法对其执行哈希引用操作。实际上，您遇到的大多数 Perl 对象都是哈希引用，但情况并非总是如此。

我不确定您想要通过使用 JSON 来编码 JSON 对象来完成什么。您需要对 JSON 对象的内部进行编码吗？或者您只需要序列化用户和所有者数据？在后一种情况下，您应该只使用新的哈希引用来保存该数据并传递给 JSON。如果您确实需要对 JSON 对象进行编码，那么使用 JSON::PP （JSON 模块的“Pure Perl”变体）可能会更好，它确实使用了哈希引用。

Answer 2

在我看来， $json = $json->utf8; 正在用标量（$json->utf8 的结果）替换 $json 哈希引用。

在分配给 $json->{...} 的行之前，使用 Data::Dumper 模块中的 Dumper 查看其中的内容。

use Data::Dumper;
print Dumper($json);

Answer 3

因为在你的例子中 $json 是编码器本身，它是对 SCALAR 的引用。尝试使用不同的变量来保存结果。像这样的东西

my %json_result = (users => $json->encode(\%user_result),
                   owners => $json->encode(\%owner_result));

Answer 4

你的大问题是 $json 是 JSON 编码器对象，而不是要编码的数据结构。您应该制作一个单独的数据结构。

您的另一个问题是您正在尝试对 JSON 进行双重编码。此代码：

my $data; # I've added this to fix your first bug
$data->{"users"}   = $json->encode(\%user_result);
$data->{"owners"}  = $json->encode(\%owner_result);

$json_string = to_json($data);

将创建一个 JSON 字符串，解码后，将为您提供带有两个键的哈希值。每个键的值都是一个包含 JSON 编码哈希的字符串。每个值都是一个哈希值更有意义。

所以，试试这个：

my $json_string = $json->encode({
  users  => \%user_result,
  owners => \%owner_result,
});

在这里，我使用匿名哈希引用，因为不需要为要编码的哈希提供名称。我们只使用一次。