当第一个小时数字为零时，向文件名添加时间戳

Question

在 Windows 2008 机器上，如果以下行位于 09:59 之后和 00:00 之前，则可以正常工作。

REN "D:\myfile.out" myfile-%DATE:/=%-%TIME::=%%.out

但是，如果我在 10:00 之前执行此操作，则会出现语法错误。它似乎试图用空格而不是零来重命名该文件。这会导致错误。例如：

Myfile-120511- 95343.out - 

我需要它保存而不会出现这样的错误：

Myfile-120511-095343.out

任何帮助将不胜感激。

Answer 1

您需要及时编辑掉前导空格以及编辑冒号（:)

set FormatedTime=%Time: =0%

REN "D:\myfile.out" myfile-%DATE:/=%-%FormatedTime::=%.out

Answer 2

您必须考虑前导空格以及区域设置日期和时间格式。

我使用这段代码，（1）暂时将日期和时间格式字符串更改为众所周知的格式，（2）通过适当的空格处理来解析返回的％date％和％time％，以及（3）放置一个完整的LODDATETIME 变量中的时间戳。

:logdatetime
reg copy "HKCU\Control Panel\International" "HKCU\Control Panel\International-Temp" /f >nul
reg add "HKCU\Control Panel\International" /v sShortDate /d "yyyy-MM-dd" /f >nul
set LogDate=%date%
reg add "HKCU\Control Panel\International" /v sTimeFormat /d "HH:mm:ss" /f >nul
set LogTime=%Time%
reg copy "HKCU\Control Panel\International-Temp" "HKCU\Control Panel\International" /f >nul
set loghour=%logtime:~0,2%
if "%loghour:~0,1%" == " " set loghour=0%loghour:~1,1%
set logmin=%logtime:~3,2%
if "%logmin:~0,1%" == " " set logmin=0%logmin:~1,1%
set logsec=%logtime:~6,2%
if "%logsec:~0,1%" == " " set logsec=0%logsec:~1,1%
set logyear=%logdate:~0,4%
set logmonth=%logdate:~5,2%
if "%logmonth:~0,1%" == " " set logmonth=0%logmonth:~1,1%
set logday=%logdate:~8,2%
if "%logday:~0,1%" == " " set day=0%day:~1,1%
set logdatetime=%logyear%%logmonth%%logday%%loghour%%logmin%%logsec%
goto :eof

要在代码中使用它，只需在bat的开头调用它并使用返回的LOGDATETIME变量

CALL :logdatetime
...
REN "D:\myfile.out" myfile-%LOGDATETIME%.out