如何根据 XML 深度通过 XSLT 更改标头级别

Question

我的 XSL 文件：

        ...
        <div>

          <xsl:choose>
            <xsl:when test="count(ancestor::node()) = 1">
              <h2>
            </xsl:when>
            <xsl:when test="count(ancestor::node()) = 2">
              <h3>
            </xsl:when>
          </xsl:choose> 

            <xsl:attribute name="id">
              <xsl:value-of select="@id" />
            </xsl:attribute>
            <xsl:copy-of select="title/node()"/>

          <xsl:choose>
            <xsl:when test="count(ancestor::node()) = 1">
              </h2>
            </xsl:when>
            <xsl:when test="count(ancestor::node()) = 2">
              </h3>
            </xsl:when>
          </xsl:choose> 

        </div>

我知道不允许像这样分割标签 h2.../h2、h3.../h3。

但如何正确地做到这一点呢？

Answer 1

您可以使用递归模板来完成此操作并动态生成标题元素。

例如，此输入 XML：

<input>
  <level id="1">
    <title>first</title>
    <level id="2">
      <title>second</title>
      <level id="3">
        <title>third</title>
      </level>
    </level>
  </level>
</input>

由此 XSLT 处理：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" exclude-result-prefixes="xsl">
<xsl:output omit-xml-declaration="yes" indent="yes" method="html"/>
<xsl:strip-space elements="*"/>

<xsl:template match="level">
  <xsl:variable name="level" select="count(ancestor-or-self::level) + 1"/>

  <xsl:element name="h{$level}">
    <xsl:attribute name="id">
      <xsl:value-of select="@id"/>
    </xsl:attribute>
    <xsl:copy-of select="title/node()"/>
  </xsl:element>

  <xsl:apply-templates select="level"/>
</xsl:template>
</xsl:stylesheet>

给出以下 HTML：

<h2 id="1">first</h2>
<h3 id="2">second</h3>
<h4 id="3">third</h4>

Answer 2

你可以使用

<xsl:template match="/div">
  <h1><xsl:apply-templates/></h1>
</xsl:template>

<xsl:template match="/*/div">
  <h2><xsl:apply-templates/></h2>
</xsl:template>

<xsl:template match="/*/*/div">
  <h3><xsl:apply-templates/></h3>
</xsl:template>