实施 IReportServerCredentials 错误

Question

我使用示例代码来实现 IReportServerCredentials 以发送登录信息以远程检索报告，但由于某种原因，该实现很容易出错。

 Imports System.Net
 Imports Microsoft.Reporting.WebForms
 Imports System.Security.Principal


   <Serializable()> _
  Public NotInheritable Class ReportServerNetworkCredentials
   Implements IReportServerCredentials


#Region "IReportServerCredentials Members"


''' <summary>
''' Specifies the user to impersonate when connecting to a report server.
''' </summary>
''' <value></value>
''' <returns>A WindowsIdentity object representing the user to impersonate.</returns>
Public ReadOnly Property ImpersonationUser() As WindowsIdentity Implements IReportServerCredentials.ImpersonationUser
    Get
        Return Nothing
    End Get
End Property

''' <summary>
''' Returns network credentials to be used for authentication with the report server.
''' </summary>
''' <value></value>
''' <returns>A NetworkCredentials object.</returns>
Public ReadOnly Property NetworkCredentials() As System.Net.ICredentials Implements IReportServerCredentials.NetworkCredentials
    Get

        dim userName As String = _
            ConfigurationManager.AppSettings("MyReportViewerUser")

        If (String.IsNullOrEmpty(userName)) Then
            Throw New Exception("Missing user name from web.config file")
        End If

        Dim password As String = _
            ConfigurationManager.AppSettings("MyReportViewerPassword")

        If (String.IsNullOrEmpty(password)) Then
            Throw New Exception("Missing password from web.config file")
        End If

       Dim domain As String = _
            ConfigurationManager.AppSettings("MyReportViewerDomain")

        If (String.IsNullOrEmpty(domain)) Then
            Throw New Exception("Missing domain from web.config file")
        End If


        Return New System.Net.NetworkCredential(userName, password, domain)
    End Get
End Property

''' <summary>
''' Provides forms authentication to be used to connect to the report server.
''' </summary>
''' <param name="authCookie">A Report Server authentication cookie.</param>
''' <param name="userName">The name of the user.</param>
''' <param name="password">The password of the user.</param>
''' <param name="authority">The authority to use when authenticating the user, such as a Microsoft Windows domain.</param>
''' <returns></returns>
Public Function GetFormsCredentials(ByVal authCookie As System.Net.Cookie, ByVal userName As String, ByVal password As String, ByVal authority As String) As Boolean Implements IReportServerCredentials.GetFormsCredentials
    authCookie = Nothing
    userName = Nothing
    password = Nothing
    authority = Nothing

    Return False
End Function

#End Region

End Class

类声明上有一个错误行

 Implements IReportServerCredentials

，它表示类必须实现函数 getformscredentials....for 接口 microsoft.reporting.webforms.ireportservercredentials...

现在，当我相应地更改函数时，它仍然给出同样的错误。

Answer 1

我假设这是完整的错误消息：

“公共函数 GetFormsCredentials(authCookie As System.Net.Cookie, userName As String,password As String,authority As String) As Boolean”和“公共函数 GetFormsCredentials(ByRef authCookie As System.Net.Cookie, ByRef userName As String) 、ByRef 密码作为字符串、ByRef 权限作为字符串) As Boolean' 不能互相重载，因为它们仅在声明为 'ByRef' 或 'ByVal' 的参数上有所不同。

在 MSDN 文档的语法部分中 IReportServerCredentials.GetFormsCredentials 您会看到声明的示例代码。

'Declaration

Function GetFormsCredentials ( _
    <OutAttribute> ByRef authCookie As Cookie, _
    <OutAttribute> ByRef userName As String, _
    <OutAttribute> ByRef password As String, _
    <OutAttribute> ByRef authority As String _
) As Boolean

您的函数声明缺少 ByRef 关键字和每个参数的 OutAttribute。 ByRef 属性告诉 VB.NET 编译器将参数的值传递回调用者。 OutAttribute 告诉编译器构建调用代码，它不需要在传入参数之前初始化参数。您可以从 Directional Attributes MSDN 上的文章以及 Lasse V. Karlsen 关于 StackOverflow 关于 属性。

OutAttribute 是在 System.Runtime.InteropServices 命名空间中声明的，因此您需要在文件顶部添加此 Import 语句。

Imports System.Runtime.InteropServices

你的函数应该看起来更像这样：

Public Function GetFormsCredentials(<OutAttribute()> ByRef authCookie As System.Net.Cookie, <OutAttribute()> ByRef userName As String, <OutAttribute()> ByRef password As String, <OutAttribute()> ByRef authority As String) As Boolean Implements IReportServerCredentials.GetFormsCredentials
    authCookie = Nothing
    userName = Nothing
    password = Nothing
    authority = Nothing

    Return False
End Function