通过 Groovy 中的嵌套闭包传递委托

Question

我正在创建一个接受 Groovy 闭包作为标记的构建器。但是，我在捕获带有嵌套闭包的方法调用时遇到了问题。

Closure nested = {
   foo ()       //will throw missingMethod exception
}
Closure root = {
   foo ()       //prints 'missing foo []'
   inline_nested {
     foo ()     //prints 'missing foo []'
   }
   nested ()    
}
builder.execute (root)

// ...
class MyBuilder {
  void execute (Closure closure) {
    def clone = closure.clone()
    clone.delegate = this
    clone()
  }
  def missingMethod (String name, args) {
     println "missing ${name} ${args}"
  }
}

有什么方法可以设置嵌套闭包的委托属性吗？

Answer 1

如果你想编写一个构建器，你应该考虑扩展 BuilderSupport 而不是自己从头开始编写。它负责将每个方法调用委托给正确的对象。

这是我编写的 JSON 构建器的示例扩展这个类。

Answer 2

我会选择不，你不能。你可能不需要它。
第一的。您是闭包的所有者或代表。如果您直接调用其他地方定义的闭包，则无需构建器的帮助即可解决该调用。
第二。你真的需要那个nested()吗？我相信您可以轻松地使用执行嵌套，而不是

这里是我的意思的一个示例，

def nested2 = {
  someMethodAtNested2 '3'
  println "nested2! - $it"
}
def nested1 = {arg1,arg2->
  someMethodAtNested1 '2'
  println "nested1! - $arg1"
  include nested2, arg2
}
def root = {
  someMethodAtRoot '1'
  println "root!"
  include nested1, 'param1', 'param2'
}
new FooBuilder().build root

class FooBuilder {
  void build(Closure closure) {
    include closure
  }
  def include(Closure closure, ...args) {
    def clone = closure.clone()
    clone.delegate = this
    clone.resolveStrategy = Closure.DELEGATE_FIRST
    clone(*args)
  }
  def methodMissing(String name, args) {
    println "missing ${name} ${args}"
  }
}

作为旁注，我不认为构建器支持是可行的方法。它对于在 java 中创建构建器可能很有用。但纯粹的常规要容易得多。至少对于中小型复杂的构建器来说是这样（从来没有写过一个非常大的构建器）。
不过，您确实需要一些有关 groovy 方法调度过程的知识