直接向打印机发送命令的正确方法！

Question

好的，我是这样做的：

procedure TMainWindow.btnRawPrintClick(Sender: TObject);
begin
  BeginPrint;
  SendStr(#27#69);
  SendStr('MyData');
  SendStr(#10);
  EndPrint;
end;

procedure TMainWindow.SendStr(Text: String);
var
  i: Integer;
  data : Array of Char;
begin
  for i := 1 to Length(Text) do
  begin
    SetLength(data,i);
    data[Pred(i)] := Text[i];
  end;

  if (PrintRawData(printHandle,
                   data,
                   Length(data)) < 0) then begin
    ShowMessage('PrintRawData Failed');
    EndRawPrintPage(printHandle);
    EndRawPrintJob(printHandle);
    exit;
  end;
end;

procedure TMainWindow.BeginPrint;
begin
  printHandle := StartRawPrintJob('EPSON TM-T70 Receipt','ESDPRT001','Test Document');

  if printHandle < 0 then
  begin
    ShowMessage('StartRawPrintJob Failed!');
    exit;
  end;

  if (StartRawPrintPage(printHandle) < 0) then begin
    ShowMessage('StartRawPrintPage Failed!');
    EndRawPrintJob(printHandle);
    exit;
  end;
end;

procedure TMainWindow.EndPrint;
begin
  if (EndRawPrintPage(printHandle) < 0) then begin
    ShowMessage('EndRawPrintPage Failed');
    EndRawPrintJob(printHandle);
    exit;
  end;

  if (EndRawPrintJob(printHandle) < 0) then begin
    ShowMessage('EndRawPrintJob Failed');
    exit;
  end;
end;

我还更改了一些从 此处：

function PrintRawData(hPrn : THandle;
                      Buffer : pointer;
                      NumBytes : SpoolInt) : integer;
{$IFDEF WIN32}
var
  BytesWritten : DWORD;
 {$ENDIF}
begin
  NumBytes := NumBytes * 2;    //<-- I added this line
  ...

但是，出现问题，因为某些命令（转义序列）无法按预期工作！

Answer 1

您使用了错误的功能。使用 Escape，将 PASSTHROUGH 标志作为第二个参数。这会将原始的、未处理的转义码直接发送到打印机。

Joe Hecht（Borland 前任成员）多次发布了一个单元，使这变得更容易。我找到了单元PrtRaw 在这里。

Answer 2

由于 Ansi 和 Unicode 字符之间的变化，您当前的代码以错误的格式向打印机发送数据。您使用的打印机显然能够容忍一定量的错误，这就是您的某些命令有效的原因，但有一个限制。

在您的 Delphi 版本中，Char 相当于 WideChar，因此请将您的 Char 代码更改为使用 AnsiChar，这样您就可以按照打印机的预期发送一字节字符。您的 PrintRawData 函数以前没问题。你的改变是错误的。打印机不期望接收两字节 Unicode 字符，但这就是您所做的更改。

恢复原始 PrintRawData 代码后，将 SendStr 函数更改为：

procedure TMainWindow.SendStr(const Text: string);
var
  data: AnsiString;
begin
  data := Text;

  if (PrintRawData(printHandle,
                   PAnsiChar(data),
                   Length(data)) < 0) then begin
    ShowMessage('PrintRawData Failed');
    EndRawPrintPage(printHandle);
    EndRawPrintJob(printHandle);
  end;
end;

我对代码进行了以下更改：

1. 将 Char 数组替换为AnsiString。
2. 不要通过循环一次一个字符地增加数据数组，而是使用单个赋值语句进行 Unicode 到 Ansi 的转换，并让 RTL 负责转换。
3. 将数据字符串类型转换为 PAnsiChar 以传递给 PrintRawData。
4. 将字符串参数作为 cons 传递，除非您需要修改它们的内容。
5. 当函数已经完成时，不需要显式的 exit 语句。

Answer 3

Procedure StrLstYazdir(pYazilacakListe: TStringList; pYazici: String);
var
  hPrn: THandle;
  yazilacakVeri: AnsiString;
  intA: Integer;
begin
  hPrn := StartRawPrintJob(PChar(pYazici), '', 'Varakim');
  if (Integer(hPrn) < 0) then
  Begin
    ShowMessage('StartRawPrintJob Hatalı');
    Exit;
  End;

  if (StartRawPrintPage(hPrn) < 0) then
  Begin
    ShowMessage('StartRawPrintPage Hatalı');
    EndRawPrintJob(hPrn);
    Exit;
  end;

  For intA := 0 to pYazilacakListe.Count - 1 do
  Begin
    yazilacakVeri := pYazilacakListe[intA] + #13 + #10;

    if (PrintRawData(hPrn, PAnsiChar(yazilacakVeri), Length(yazilacakVeri)) < 0)
    then
    begin
      ShowMessage('PrintRawData Hatalı');
      EndRawPrintPage(hPrn);
      EndRawPrintJob(hPrn);
      Exit;
    End;
  End;
  if (EndRawPrintPage(hPrn) < 0) then
  begin
    ShowMessage('EndRawPrintPage Hatalı');
    EndRawPrintJob(hPrn);
    Exit;
  End;

  if (EndRawPrintJob(hPrn) < 0) then
  begin
    ShowMessage('EndRawPrintJob Hatalı');
    Exit;
  End;
End;

用法：

StrLstYazdir(Memo1.Lines ,'Lexmark Forms Printer 2491')