对于目录中的每个xml文件，如何将其内容添加到某个位置的另一个文件中？

Question

我有一个有趣且看似简单的 Perl 挑战，困扰着我的同事。介意破解吗？这将真正帮助我的项目取得进展。

迭代directoryD 中的每个xmlfileXF，并对每个文件：

1. 在modifythisfileMTF 中，复制wordblockWB 并将其粘贴到最后一个wordblockWB 后面。
2. 在modifythisfileMTF中，将replacemeRM替换为当前xmlfileXF的内容。

顺便说一下，directoryD 只有 xml 文件，所以实际上，您不必区分文件类型。另外，如果您愿意，也可以对 wordblockWB 的内容进行硬编码。

修改这个文件MTF.txt 内容：

myfunc
{
  // begin wordblockWB
  prewords
  "msg"=replacemeRM
  postwords
  // end   wordblockWB

  return 0;
}

directoryD 内容：

xmlfileXF1.xml
xmlfileXF2.xml
...6000 more

xmlfileXF1.xml 内容：

<foo/>

xmlfileXF2.xml 内容：

<bar/>

所需的输出 修改这个文件MTF.txt 内容：

myfunc
{
  // begin wordblockWB
  prewords
  "msg"=<foo/>
  postwords
  // end   wordblockWB

  // begin wordblockWB
  prewords
  "msg"=<bar/>
  postwords
  // end   wordblockWB

  return 0;
}

感谢所有帮助，祝您玩得开心！

Answer 1

这应该可以完成工作。它打印到 STDOUT，因此只需根据需要重定向到文件即可。

#!/usr/bin/perl

use strict;
use warnings;

my $directoryD = "/xml files";
my $prewords = "Four score and...\n";
my $postwords = "The End\n";

chdir("$directoryD") or die $!;
opendir(D, ".") or die $!;
my @xmlFiles = grep(/\.xml$/i, readdir(D));
closedir(D);
if (scalar(@xmlFiles) == 0) {
  die "Could not detect any XML files in $directoryD\n";
}

print "myfunc\n";
print "{\n";
foreach my $file (@xmlFiles) {
  # Read the FIRST line from each file.  Ignore any other lines.
  open(F, "$file") or die $!;
  my $line = <F>;
  chomp $line;
  close(F);

  print $prewords;
  print "\"msg\"=$line\n";
  print $postwords;
  print "\n";
}
print "return 0;\n";
print "}\n";

Answer 2

这是打印到标准输出的另一种可能的解决方案：

#!/usr/bin/env perl

use strict;
use warnings;

my $dir = shift || '.';

doit(sub {
    my $callback = shift;

    opendir(my $dh, $dir) or die $!;
    while(my $file = readdir($dh)) {
        next unless $file =~ /\.xml$/i;

        open (my $fh, '<', $file) or die $!;
        chomp(my $line = <$fh>);
        close($fh) or die $!;

        $callback->($line);
    }
    closedir($dh) or die $!;
});

sub doit {
    my $process_files = shift;

    print "myfunc\n{\n";
    $process_files->(sub {
        my $msg = shift;
        print join "\n", map { "\t$_" } (
                '// begin wordblockWB',
                'prewords',
                qq{"msg"=$msg},
                'postwords',
                '// end wordblockWB',
                "\n"
            );
    });
    print "\treturn 0;\n}\n";
}

它有点冗长，但其想法是将文件处理代码和格式化/输出代码分开。但在这种情况下，额外的复杂性可能不值得。