在 AS3 的子类中序列化向量时出现问题

Question

嘿！我正在尝试在 AS3 中序列化数据，但遇到了一个令人沮丧的问题。最初，我遇到了“myObjClass”不可转换的问题，但在我发现“registerClassAlias”之后，我的工作一切正常。

一段时间后，我将向量添加到 myObjClass 中。我之前遇到过向量字符串的麻烦，如下所示：

https://bugs.adobe .com/jira/browse/FP-6693

所以我知道解决方法是包括：

registerClassAlias("String", String);

我只是不确定如何为向量内的子向量（以及其他变量）注册别名。这是我的代码：

var newObj:myObjClass = new myObjClass();
newObj.mySubXML = new Vector.<XML>();
newObj.mySubString = new Vector.<String>();

var myObj:Vector.<myObjClass> = new Vector.<myObjClass>();
myObj.push(newObj);

registerClassAlias("String", String); // Problem #1
registerClassAlias("XML", XML);       // Problem #1
registerClassAlias("VecMyObjClass", Vector.<myObjClass> as Class); // Problem #2
// registerClassAlias("myObjClass", myObjClass); // This and the above are interchangable (same errors)
var bytes:ByteArray = new ByteArray();
bytes.writeObject(myObj);
bytes.position = 0;
myObj = bytes.readObject();

问题#1：当这两行包含在我的编译中时，最后一行 (bytes.readObject()) 失败并出现错误：

Error #1034: Type Coercion failed: cannot convert __AS3__.vec::Vector.<Object>@42edb21 to __AS3__.vec.Vector.<myObjClass>.

这真的很奇怪。就好像前两个 registerClassAlias 正在撤销第三个。

问题#2：如果我注释掉两个“第一个问题”行（字符串/xml 类别名注册），它会将 myObj 转换为 myObjClass 就好；不会引发内部错误，并且应用程序不会停止。但是，它无法转换内部 String 和 XML 向量，应用程序输出中出现此错误（不停止）：

TypeError: Error #1034: Type Coercion failed: cannot convert __AS3__.vec::Vector.<Object>@3aabc11 to __AS3__.vec.Vector.<XML>.
TypeError: Error #1034: Type Coercion failed: cannot convert __AS3__.vec::Vector.<Object>@3aabc41 to __AS3__.vec.Vector.<String>.

所以我的问题是，如何注册一个类别名：

• Vector.(myObjClass)
• 字符串向量为Vector.(myObjClass) 的属性
• XML 向量作为 Vector.(myObjClass) 的属性

全部同时？

Answer 1

看起来像直接移动：

registerClassAlias("XML", XML);
registerClassAlias("String", String);

进入myObjClass就达到了目的，同时保留：

registerClassAlias("myObjClass", myObjClass);

在序列化类中。我不确定为什么将这三个存储在序列化类中不起作用 - 如果我更改代码的顺序，则会生成奇怪的错误，因此问题可能只是特定机器上的一些故障。

Answer 2

当您想使用复杂的矢量内容时，您必须注册每个子类（为您的 Vector.[String]），如下所示：

    package
{
    import flash.display.Sprite;
    import flash.net.registerClassAlias;
    import flash.utils.ByteArray;

    public class StackOverFlow extends Sprite
    {
        public function StackOverFlow()
        {
            var newObj:myObjClass = new myObjClass();
            newObj.mySubXML = new Vector.<XML>();
            newObj.mySubString = new Vector.<String>();

            var myObj:Vector.<myObjClass> = new Vector.<myObjClass>();
            myObj.push(newObj);

            registerClassAlias("String", String);
            registerClassAlias("XML", XML);
            registerClassAlias("myObjClass", myObjClass);
            registerClassAlias("VecMyObjClass", Vector.<myObjClass> as Class);
            var bytes:ByteArray = new ByteArray();
            bytes.writeObject(myObj);
            bytes.position = 0;
            myObj = bytes.readObject();
        }
    }
}

internal class myObjClass{
    public var mySubXML : Vector.<XML>;
    public var mySubString : Vector.<String>;
}

Answer 3

测试您的代码 Andy，您需要注册您创建的类，以便 bytes.readObject() 返回带有自定义类的向量 - 在本例中为类 myObjClass。因此，如果您添加这行代码：

registerClassAlias("myObjClass", myObjClass);

因此，如果您将代码更改为如下所示，那么您应该返回所有数据都正确序列化的对象（我做了一个简单的测试，它似乎对我有效）。

var newObj:myObjClass = new myObjClass();
newObj.mySubXML = new Vector.<XML>();
newObj.mySubString = new Vector.<String>();

var myObj:Vector.<myObjClass> = new Vector.<myObjClass>();
myObj.push(newObj);

registerClassAlias("String", String);
registerClassAlias("XML", XML);
registerClassAlias("myObjClass", myObjClass);
var bytes:ByteArray = new ByteArray();
bytes.writeObject(myObj);
bytes.position = 0;
myObj = bytes.readObject();

Answer 4

registerClassAlias("String", String);    
registerClassAlias("VecString", Vector.<String> as Class); 

registerClassAlias("XML", XML);    
registerClassAlias("VecXML", Vector.<XML> as Class); 

registerClassAlias("myObjClass", myObjClass);    
registerClassAlias("VecMyObjClass", Vector.<myObjClass> as Class);