返回文件是否存在 VBA Mac Office 2011

Question

我正在尝试测试 Mac Office 2011 上的 VBA 是否存在文件。

我的宏适用于 Office 2004，但不适用于 2011。

我正在使用 Dir 函数。如果该函数没有返回任何内容，则意味着该文件不存在。但在 Office 2011 中，当文件不存在时，该函数会返回错误代码 76。

Answer 1

您可以创建自己的函数来处理错误。例如，这样的事情：

Function FileExists(ByVal AFileName As String) As Boolean
    On Error GoTo Catch

    FileSystem.FileLen AFileName

    FileExists = True

    GoTo Finally

    Catch:
        FileExists = False
    Finally:
End Function

Sub Test()
  If FileExists("Macintosh HD:Library:User Pictures:Flowers:Flower.tif") Then
    MsgBox "File exists"
  Else
    MsgBox "File doesn't exists"
  End If
End Sub

Answer 2

答案 1 中的解决方案应该有效。但每当您遇到困扰 Mac Excel 2011 的截断文件名问题时，即使应用了 SP1，也会失败。

Microsoft 上描述了基本问题
http://answers.microsoft.com/en-us/mac/forum/macoffice2011-macexcel/help-xl-2011s-dir-function -truncates-filename/e72fbf5d-749c-4a55-a77c-e2def6db24d9?msgId=644b9f20-251b-46fe-8df3-f5a28a1c37f6

和 FileSystem 对象与使用 VBA 原生 Dir 函数具有相同的疾病。

换句话说，它返回与 Dir 返回的相同的截断文件名，因此您实际上无法使用 Excel 2011 后面的 VBA 确定是否存在具有长名称的文件（该名称实际出现在 Finder 列表中的用户） SP1，无需借助 AppleScripting！

Answer 3

更好的答案在 msft 网站上： http:// /msdn.microsoft.com/en-us/library/office/jj614412(v=office.14).aspx

例如：

Sub TestFile()
'First argument, 1 = file and 2 = folder.
'Note: This macro uses the FileOrFolderExistsOnMac function.
    If FileOrFolderExistsOnMac(1, "Macintosh HD:Users:<user name>:Documents:YourFileName.xlsx") = True Then
        MsgBox "File exists."
    Else
        MsgBox "File does not exist."
    End If
End Sub

Sub TestFolder()
'First argument, 1 = file and 2 = folder.
'Note: This macro uses the FileOrFolderExistsOnMac function.
    If FileOrFolderExistsOnMac(2, "Macintosh HD:Users:<user name>:Documents") = True Then
        MsgBox "Folder exists."
    Else
        MsgBox "Folder does not exist."
    End If
End Sub

Function FileOrFolderExistsOnMac(FileOrFolder As Long, FileOrFolderstr As String) As Boolean
'By Ron de Bruin
'30-July-2012
'Function to test whether a file or folder exist on a Mac.
'Uses AppleScript to avoid the problem with long file names.
    Dim ScriptToCheckFileFolder As String
    ScriptToCheckFileFolder = "tell application " & Chr(34) & "Finder" & Chr(34) & Chr(13)
    If FileOrFolder = 1 Then
        ScriptToCheckFileFolder = ScriptToCheckFileFolder & "exists file " & _
        Chr(34) & FileOrFolderstr & Chr(34) & Chr(13)
    Else
        ScriptToCheckFileFolder = ScriptToCheckFileFolder & "exists folder " & _
        Chr(34) & FileOrFolderstr & Chr(34) & Chr(13)
    End If
    ScriptToCheckFileFolder = ScriptToCheckFileFolder & "end tell" & Chr(13)
    FileOrFolderExistsOnMac = MacScript(ScriptToCheckFileFolder)
End Function