Groovy 将代码添加到构造函数

Question

Groovy 中有没有一种方法可以在实例化类时向构造函数添加代码？我有一个 Groovy 类（但我无法修改这个特定类的源代码），但我希望有一种方法可以注入代码（也许通过元类），以便我的代码作为构造函数的一部分运行（在此如果只有一个，默认构造函数）。

谢谢， 杰夫

Answer 1

您可以重写构造函数，但这有点棘手，特别是当您重写默认构造函数时。您需要为类的 metaClass.constructor 分配一个闭包，并且该闭包应返回一个新实例。棘手的部分是，如果您调用已重写的构造函数，您将进入递归循环并生成堆栈溢出。您需要另一种方法来获取该类的实例，例如不同的构造函数。

对于测试，有时可以绕过此限制。通常，首先实例化一个对象，然后重写构造函数以返回现有实例就足够了。例子：

class MyObject {
    String something
    MyObject() { something = "initialized" }
}

testInstance = new MyObject()
testInstance.something = "overriden"
MyObject.metaClass.constructor = { -> testInstance }

aNewObject = new MyObject()
assert aNewObject.is(testInstance)
assert aNewObject.something == "overriden"

Answer 2

可以添加新的构造函数或替换旧的构造函数。如果您需要原始构造函数，则可以使用反射：

MyObject.metaClass.constructor = { -> // for the no-arg ctor
  // use reflection to get the original constructor
  def constructor = MyObject.class.getConstructor()
  // create the new instance
  def instance = constructor.newInstance()
  // ... do some further stuff with the instance ...
  println "Created ${instance}"
  instance
}

请注意，如果您的构造函数有参数，则必须更改此设置，例如：

// Note that the closure contains the signature of the constructor
MyObject.metaClass.constructor = { int year, String reason ->
  def constructor = MyObject.class.getConstructor(Integer.TYPE, String.class)
  def instance = constructor.newInstance(
    2014, "Boy, am I really answering a question three years old?")
  // ... do some further stuff with the instance ...
  println "Created ${instance}"
  instance
}

PS：请注意，当您要添加尚不存在的构造函数时，请使用 < code><< 运算符改为：MyObject.metaClass.constructor << { /* 如上 */ }。

Answer 3

您可以通过使用标准 Java 反射存储原始构造函数来绕过所提出的解决方案中的限制。例如，这就是我在 spock 测试中初始化一个类（基本注入）的方法：

def setupSpec() {
    MockPlexusContainer mockPlexusContainer = new MockPlexusContainer()
    def oldConstructor = MY_CLASS.constructors[0]

    MY_CLASS.metaClass.constructor = { ->
        def mojo = oldConstructor.newInstance()
        mockPlexusContainer.initializeContext(mojo)
        return mojo
    }
}

它仅被调用一次，但每次有人调用构造函数时，我都会得到一个不同的实例，从而避免清理值并确保线程安全。