Excel 工作表页脚中的上次保存日期

Question

我正在将 Excel 2007 与包含许多工作表的工作簿一起使用。我需要在页脚中包含上次保存工作表的日期。我能够找到以下内容：

Private Sub Workbook_BeforeSave(ByVal SaveAsUI As Boolean, Cancel As Boolean)

Dim ws As Worksheet

For Each ws In ThisWorkbook.Worksheets
With ws.PageSetup
.LeftFooter = "Last Save Time: &T"
.RightFooter = "Last Save Date: &D"
End With
Next ws

Set ws = Nothing

End Sub

这会更改每个工作表。我需要它只更改已编辑的工作表（因此每个工作表可以有不同的日期）。 这可能吗？我应该使用单元格而不是页脚吗？或者我必须创建多个工作簿吗？

谢谢！

Answer 1

正如 Remnant 所建议的，最好的方法是利用 Worksheet_Change 事件。 需要此 VBA 代码

Private Sub Worksheet_Change(ByVal Target As Range)
    With Me.PageSetup
        .LeftFooter = "Last Change Time: " & Format(VBA.Time, "hh:mm:ss")
        .RightFooter = "Last Change Date: " & Format(VBA.Date, "dd/mm/yy")
    End With
End Sub

这意味着，您的每个工作表中都 。仅当您更改单元格内容时才会引发此事件，而不是在更改选择时引发，因此它可能是您想要的。

Remnant 还写道，如果您有很多工作表，这将是“设置起来很痛苦”。我认为这取决于你所说的“很多”。对于最多 20~40 个工作表，可以在几分钟内轻松地将上面的代码手动复制到每张工作表中。

如果您已经有一个工作簿和很多（例如，超过 40 张）工作表，那么以编程方式添加代码可能是个好主意。将包含此代码的单独模块添加到您的工作簿中，并运行一次：

Option Explicit
Sub InsertCode()
    Dim VBProj As Object
    Dim VBComp As Object
    Dim CodeMod As Object
    Dim sh As Worksheet
    Dim LineNum As Long

    Set VBProj = ActiveWorkbook.VBProject
    For Each sh In ThisWorkbook.Sheets
        Set VBComp = VBProj.vbcomponents(sh.Name)
        Set CodeMod = VBComp.CodeModule
        With CodeMod
            .DeleteLines 1, .CountOfLines
            LineNum = .CreateEventProc("Change", "Worksheet")
            LineNum = LineNum + 1
            .InsertLines LineNum, "Me.Pagesetup.LeftFooter = ""Last Change Time: "" & Format(VBA.Time, ""hh:mm:ss"")"
            .InsertLines LineNum + 1, "Me.Pagesetup.RightFooter = ""Last Change Date: "" & Format(VBA.Date, ""dd/mm/yy"")"
        End With
    Next
End Sub

这会将上面的“Worksheet_Change”事件添加到每个工作表的代码部分。

Answer 2

它修改每个工作表的原因是因为您正在执行“For Each WS in ThisWorkbook.Worksheets”。将其更改为仅查找您要修改的工作表，然后您就可以开始了。

例如，如果您没有要修改的工作表的引用，请保留 For Each 循环，但不要修改每个工作表，而是检查工作表以查看它是否是您想要的工作表。如果是，请修改页脚。否则，忽略它。

Answer 3

一种选择可能是每次更改工作表时更新页脚。这意味着各个工作表将具有不同的日期/时间，具体取决于更新时间。

Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)
    With Sh.PageSetup
        .LeftFooter = "Last Save Time: " & Format(VBA.Time, "hh:mm:ss")
        .RightFooter = "Last Save Date: " & Format(VBA.Date, "dd/mm/yy")
    End With
End Sub

然后用户可以正常保存工作簿。

这能满足您的需要吗？